package{
	import flash.display.*;
	public class Enemy extends Sprite {
		private var game:Gyruss;
		private var index:Number;
		private var radius:Number = 0;
		private var minRadius:Number = 10;
		private var maxRadius:Number = 160;
		private var centerX:Number;
		private var centerY:Number;
		private var angle:Number;
		private var direction:Number;					//	clockwise or counterclockwise
		private var approachDirection:Number = 1;		//	approaching or receding
		private var APPROACH_SPEED:Number = .3;			//	approach speed
		private var SPEED:Number = Math.PI*2/300;		//	rotation speed
		private var THETA:Number = Math.PI * 2;
		private var RAD_DEG:Number = Math.PI/180;
		
		public var health:Number = 100;
		
		public var isDead:Boolean = false;
		
		public function Enemy($game:Gyruss) {
			game = $game;
			centerX = game.centerX;
			centerY = game.centerY;
			
			x = centerX;
			y = centerY;
			
			setRandomDirection();
			graphics.beginFill(0xcccccc,100);
			graphics.drawRoundRect(-25,-10,50,20,5,5);
			graphics.endFill();
			
			graphics.beginFill(0xff0000,100);
			graphics.drawCircle(0,0,7);
			graphics.endFill();
			
			graphics.beginFill(0x000000,100);
			graphics.drawCircle(0,0,3);
			graphics.endFill();
			
		}
		
		public function setDirection($d:Number):void {
			direction = $d;
		}
		public function setRandomDirection():void {
			direction = (Math.round(Math.random())*2)-1;
			direction = 1;
		}
		
		public function move():void {
			THETA += (SPEED * direction);
			x = centerX + (radius * Math.cos(THETA));
			y = centerY + (radius * Math.sin(THETA));
			rotation = Math.atan2(y-centerY,x-centerX)/RAD_DEG;
			scaleX = scaleY = radius/maxRadius;
			if((radius < maxRadius && approachDirection==1) || (radius > minRadius && approachDirection == -1)) {
				radius += (APPROACH_SPEED*approachDirection);
			} else {
				approachDirection *= -1;
			}
		}
		
		public function takeDamage($d:Number):void {
			health -= $d;
			if(health <= 0) explode();
		}
		public function explode():void {
			isDead = true;
		}
	}
}

package{
	import flash.display.*;
	import flash.events.*;
	import flash.ui.Keyboard;
	import flash.geom.*;
	import flash.filters.BlurFilter;
	[SWF(backgroundColor="0x000000",width="540",height="540",frameRate="50")]
	public class KeyCodes extends Sprite {
		/*					*/
		/*	EMBEDDED ASSETS	*/
		/*					*/
		
		[Embed(source="ship_1.gif")]
		private var Ship:Class;
		private var ship:Bitmap;
		
		public var shots:Array;
		private var ball:Sprite;
		private var flame:Sprite;
		private var _bitmap:BitmapData;
		private var _buffer:BitmapData;
		private var _buffer_clear:BitmapData;	//	used to "clear" the bitmapdata
		private var _blur_layer:BitmapData;
		private var _image:Bitmap;
		private var _blurFilter:BlurFilter;
		
		private var SPEED:Number = Math.PI*2/100;	//	number of steps around a circle
		private var THETA:Number = Math.PI*.5;
		private var RAD_DEG:Number = 180/Math.PI;
		public var radius:Number;
		private var flameRadius:Number;
		public var centerX:Number;
		public var centerY:Number;
		private var angle:Number;
		
		private var isLeft:Boolean = false;
		private var isRight:Boolean = false;
		private var isFiring:Boolean = false;
		private var xDirection:Number = 0;
		public function KeyCodes() {
			_blurFilter = new BlurFilter();
			shots = [];
			addEventListener(Event.ENTER_FRAME,init);
		}
		private function init(e:Event):void {
			if(!stage) return;
			removeEventListener(Event.ENTER_FRAME,init);
			ball = new Sprite();
			ship = new Ship();
			ship.x = -(ship.width/2);
			ship.y = -(ship.height/2);
			ship.rotation = 90;
			ball.addChild(ship);
			
			flame = new Sprite();
			flame.graphics.beginFill(0x990000,100);
			flame.graphics.drawCircle(4,-10,4);
			flame.graphics.endFill();
			flame.graphics.beginFill(0x990000,100);
			flame.graphics.drawCircle(4,10,4);
			flame.graphics.endFill();
			
			centerX = stage.stageWidth/2;
			centerY = stage.stageHeight/2;
			radius = stage.stageWidth*.3;
			flameRadius = radius + (ship.height*1.5);
			ball.x = centerX + radius*Math.cos(THETA);
			ball.y = centerY + radius*Math.sin(THETA);
			flame.x = centerX + flameRadius*Math.cos(THETA);
			flame.y = centerY + flameRadius*Math.sin(THETA);
			_bitmap = new BitmapData(stage.stageWidth,stage.stageHeight,true,0xff000000);
			_buffer = new BitmapData(stage.stageWidth,stage.stageHeight,true,0x00000000);
			_buffer_clear = new BitmapData(stage.stageWidth,stage.stageHeight,true,0xff000000);
			_blur_layer = new BitmapData(stage.stageWidth,stage.stageHeight,true,0xff000000);
			_image = new Bitmap(_bitmap);
			addChild(_image);
			
			stage.addEventListener(KeyboardEvent.KEY_DOWN,setDirection);
			stage.addEventListener(KeyboardEvent.KEY_UP,unsetDirection);
			addEventListener(Event.ENTER_FRAME,moveMe);
		}
		public function moveMe(e:Event):void {
			if(isLeft==true) {
				xDirection = -1;
			} else if (isRight==true) {
				xDirection = 1;
			} else {
				xDirection = 0;
			}
			THETA += SPEED * xDirection;
			ball.x = centerX + radius*Math.cos(THETA);
			ball.y = centerY + radius*Math.sin(THETA);
			flame.x = centerX + flameRadius*Math.cos(THETA);
			flame.y = centerY + flameRadius*Math.sin(THETA);
			var r:Number = Math.atan2(centerY - ball.y , centerX - ball.x)*RAD_DEG;
			ball.rotation = r;
			flame.rotation = r;
		//	_buffer.draw(_buffer_clear);
			_blur_layer.draw(flame,flame.transform.matrix);
			for(var i:Number = 0;i<shots.length;i++) {
				if(shots[i].isDead==false) {
					shots[i].move();
					_blur_layer.draw(shots[i],shots[i].transform.matrix);
				} else {
					delete shots[i];
					shots[i] = null;
					shots.splice(i,1);
				}
			}
			_blur_layer.applyFilter(_blur_layer,_blur_layer.rect,new Point(),_blurFilter);
			_buffer.draw(_blur_layer);
			_buffer.draw(ball,ball.transform.matrix);
			_bitmap.draw(_buffer);
		}
		
		public function setDirection(e:KeyboardEvent):void {
			switch(e.keyCode) {
				case Keyboard.LEFT :
					isLeft=true;
					break;
				case Keyboard.RIGHT :
					isRight=true;
					break;
				case Keyboard.SPACE : 
					addShot();
				default:
					break;
			}
		}
		public function unsetDirection(e:KeyboardEvent):void {
			switch(e.keyCode) {
				case Keyboard.LEFT :
					isLeft = false;
					break;
				case Keyboard.RIGHT :
					isRight = false;
					break;
				case Keyboard.SPACE : 
					isFiring = false;
				default:
					break;
			}
		}
		
		public function addShot():void {
			if(isFiring==true) return;
			isFiring = true;
			var s:Shot = new Shot(this,centerX + (radius+50)*Math.cos(THETA),centerY + (radius+50)*Math.sin(THETA));
			shots.push(s);
		}
	}
}