Jump to content

  • Log In with Google      Sign In   
  • Create Account


GLSL issues between ATI and Nvidia Cards


Old topic!
Guest, the last post of this topic is over 60 days old and at this point you may not reply in this topic. If you wish to continue this conversation start a new topic.

  • You cannot reply to this topic
9 replies to this topic

#1 harshman_chris   Members   -  Reputation: 184

Like
0Likes
Like

Posted 21 January 2013 - 07:34 AM

So I am getting an issue between my home computer and my school laptop with my shaders.

 

First off this will not run on my Nvidia NVS 4200M, it supports shader model 4.2, my home computer uses a ATI 5850. I can also confirm this happens on the Nvidia GTX 260

 

#version 330 core


layout(location = 0) in vec3 vertex;
layout(location = 1) in vec2 uv;
layout(location = 2) in vec3 normal;

out vec2 uv0;
out vec3 normal0;
out vec3 worldPos0;

uniform mat4 mvp;
uniform mat4 world;

void main()
{
	gl_Position =  mvp * vec4(vertex,1.0f);
	uv0 = uv;
	normal0 = world * vec4(normal,0.0f);
	worldPos0 = world * vec4(vertex,1.0f);
}

 

However if I do this it will compile, but my fragment shader doesnt work on my Nvidia card, it works on my ATI 5850.
 

#version 330 core


layout(location = 0) in vec3 vertex;
layout(location = 1) in vec2 uv;
layout(location = 2) in vec3 normal;

out vec2 uv0;
out vec3 normal0;
out vec3 worldPos0;

uniform mat4 mvp;
uniform mat4 world;

void main()
{
	gl_Position =  mvp * vec4(vertex,1.0f);
	uv0 = uv;
	normal0 = (world * vec4(normal,0.0f)).xyz;
	worldPos0 = (world * vec4(vertex,1.0f)).xyz;
}

 

 

My fragment shader compiled but when I set lighting to on, anything with this shader will not draw, it draws with lighting off however. Both methods work on my ATI card.

 

#version 330 core

struct Attenuation
{
    int constant;
    int linear;
    int exponential;
};

struct BaseLight
{
	vec4 colour;
    float ambientIntensity;
    float diffuseIntensity;  
};

struct DirectionalLight 
{                                                                                   
    BaseLight base;
    vec3 direction;        
};

struct PointLight
{
	BaseLight base;  
    vec3 position;
	Attenuation attenuation;
};

vec3 CalcLightInternal(BaseLight _light, vec3 _lightDirection, vec3 _normal);
vec3 CalcDirectionalLight(vec3 _normal);
vec3 CalcPointLight(int _index, vec3 _normal);

const int MAX_POINT_LIGHTS = 5;

in vec2 uv0;
in vec3 normal0;
in vec3 worldPos0;

out vec3 finalColor;

uniform DirectionalLight directionalLight;
uniform PointLight pointLights[MAX_POINT_LIGHTS];

uniform int numPointLights;

uniform int lightingEnabled;

uniform vec3 cameraEyeWorldPosition;

uniform float specularIntensity;
uniform float specularPower;

uniform sampler2D diffusetexture;

void main()
{
	vec3 MaterialDiffuseColor = texture2D(diffusetexture, uv0).rgb;

	vec3 Normal = normalize(normal0);

	if(lightingEnabled == 1)
	{
		vec3 TotalLight = CalcDirectionalLight(Normal);

		for (int i = 0; i < numPointLights; i++)
		{
			TotalLight += CalcPointLight(i, Normal);
		}   

		finalColor = MaterialDiffuseColor * TotalLight;
	}
	else
	{
		finalColor = MaterialDiffuseColor;
	}
}

vec3 CalcLightInternal(BaseLight _light, vec3 _lightDirection, vec3 _normal)
{
	vec3 AmbientColor = _light.colour.rgb * _light.ambientIntensity;

	float DiffuseFactor = dot(normalize(_normal), _lightDirection);

	vec3 DiffuseColor = vec3(0, 0, 0);
	vec3 SpecularColor  = vec3(0, 0, 0);

	if (DiffuseFactor > 0) 
	{
        DiffuseColor = _light.colour.rgb * _light.diffuseIntensity * DiffuseFactor;

		vec3 VertexToEye = normalize(cameraEyeWorldPosition - worldPos0);
		vec3 LightReflect = normalize(reflect(_lightDirection, _normal));
		float SpecularFactor = dot(VertexToEye, LightReflect);
		SpecularFactor = pow(SpecularFactor, specularPower);

		if (SpecularFactor > 0) 
		{
			SpecularColor = _light.colour.rgb * specularIntensity * SpecularFactor;
		}
    }

	return (AmbientColor + DiffuseColor + SpecularColor);
}

vec3 CalcDirectionalLight(vec3 _normal)
{
    return CalcLightInternal(directionalLight.base, directionalLight.direction, _normal);
}

vec3 CalcPointLight(int _index, vec3 _normal)
{
    vec3 LightDirection = worldPos0 - pointLights[_index].position;
    float Distance = length(LightDirection);
    LightDirection = normalize(LightDirection);

    vec3 Color = CalcLightInternal(pointLights[_index].base, LightDirection, _normal);
    float Attenuation =  pointLights[_index].attenuation.constant +
                         pointLights[_index].attenuation.linear * Distance +
                         pointLights[_index].attenuation.exponential * Distance * Distance; 

    return Color / Attenuation;
}  

 

To be clear, this works on my ATI 5850


Edited by harshman_chris, 21 January 2013 - 07:58 AM.


Sponsor:

#2 Ashaman73   Crossbones+   -  Reputation: 6568

Like
0Likes
Like

Posted 21 January 2013 - 08:05 AM

In general, ATI and NVIDIA will handle not clearly defined glsl code differently. Nvidia is known for more lax handling of glsl syntax, whereas ATI often requires strict one. Best to compile and run your GLSL code as often as possible on both platforms to detect errors early enough.

 

Just guessing, but I believe, that  the pow implementation is more picky on nvidia (per definition, the behaviour of pow(x,y) is undefined if x<0 or x=0 and y=0). Therefore I would put the pow function into the if-clause:

 
if (SpecularFactor > 0)
{
SpecularFactor = pow(SpecularFactor, specularPower);
SpecularColor = _light.colour.rgb * specularIntensity * SpecularFactor;
}



Edited by Ashaman73, 21 January 2013 - 08:09 AM.


#3 harshman_chris   Members   -  Reputation: 184

Like
0Likes
Like

Posted 21 January 2013 - 08:18 AM

That did not solve the issue, but its a good tip.

 

I have been playing around with the ATI GPU ShaderAnalyzer, but I cannot find a glsl one for Nvidia.

 

Not really getting anywhere with this at the moment unfortunately.



#4 mhagain   Crossbones+   -  Reputation: 7338

Like
0Likes
Like

Posted 21 January 2013 - 11:22 AM

Try #version 330 compatibility - I've hit this before with NV and that resolved it; as for the why, I put that one down to driver voodoo, unfortunately.


It appears that the gentleman thought C++ was extremely difficult and he was overjoyed that the machine was absorbing it; he understood that good C++ is difficult but the best C++ is well-nigh unintelligible.


#5 harshman_chris   Members   -  Reputation: 184

Like
0Likes
Like

Posted 21 January 2013 - 11:27 AM

Try #version 330 compatibility - I've hit this before with NV and that resolved it; as for the why, I put that one down to driver voodoo, unfortunately.

 

Unfortunately that was one of the first things I tried before coming here :( but this driver 'voodoo' annoys me a lot.



#6 mhagain   Crossbones+   -  Reputation: 7338

Like
0Likes
Like

Posted 21 January 2013 - 04:02 PM

Just re-examining your vertex shader, here's the problem with it:

normal0 = world * vec4(normal,0.0f);

normal0 is defined as a vec3, yet the output of a mat4 * vec4 calculation will be a vec4, so you've got a vector type truncation. Your shader compile should at least have given you warnings about that, so I'd suspect that you're not checking the result of your compilation fully (or at all) using glGetShaderInfoLog and glGetProgramInfoLog.

Regarding truncations, the GLSL spec says:
 

there must be enough components provided in the arguments to provide an initializer for every component in the constructed value. It is an error to provide extra arguments beyond this last used argument

 

And
 

Accessing components beyond those declared for the vector type is an error

 

So in this case the NV compiler is strictly adhering to spec, whereas the AMD compiler is being lax and allowing things it shouldn't.

Like I said, check your glGetShaderInfoLog and glGetProgramInfoLog outputs and they should point you to further issues (you've another in your vertex shader), as well as to your fragment shader problems.


It appears that the gentleman thought C++ was extremely difficult and he was overjoyed that the machine was absorbing it; he understood that good C++ is difficult but the best C++ is well-nigh unintelligible.


#7 harshman_chris   Members   -  Reputation: 184

Like
0Likes
Like

Posted 21 January 2013 - 07:38 PM

I read my logs like this:

 

GLint logSize;
		glGetShaderiv(shader, GL_INFO_LOG_LENGTH, &logSize);

		char* logMsg = new char[logSize];
		glGetShaderInfoLog(shader, logSize, NULL, logMsg);

		Logger::getInstance()->write(StringUtils::format("Error Message: %s",logMsg));

		delete [] logMsg;

		exit(EXIT_FAILURE);

 

but this only return issues on error.

 

 

That was only part of my issue however, I bypassed that before I posted, my fragment shader is the real issue, not running when lighting is enabled, or rather everything being black.



#8 Ignifex   Members   -  Reputation: 507

Like
0Likes
Like

Posted 22 January 2013 - 05:43 AM

Just to point out a potential problem:

 

vec3 CalcPointLight(int _index, vec3 _normal) {
    vec3 LightDirection = worldPos0 - pointLights[_index].position;
    ...
}

 

It looks like your lightdirection is reversed with respect to your normal and eye vector. This could cause a lot te become black for the diffuse term and might mess up your specular computation as well (negative x in pow(x, y)), but it sounds like you solved that already.

 

What combination of lights have you used for testing? What happens when you use only a directional light?



#9 harshman_chris   Members   -  Reputation: 184

Like
0Likes
Like

Posted 22 January 2013 - 08:20 AM

Just to point out a potential problem:

 

vec3 CalcPointLight(int _index, vec3 _normal) {
    vec3 LightDirection = worldPos0 - pointLights[_index].position;
    ...
}

 

It looks like your lightdirection is reversed with respect to your normal and eye vector. This could cause a lot te become black for the diffuse term and might mess up your specular computation as well (negative x in pow(x, y)), but it sounds like you solved that already.

 

What combination of lights have you used for testing? What happens when you use only a directional light?

 

I dont actually know what you mean with that.



#10 harshman_chris   Members   -  Reputation: 184

Like
0Likes
Like

Posted 22 January 2013 - 06:48 PM

So A second post because I found out more information. The lines below each comment that are marked with an ERROR generate GL_INVALID_OPERATION, and therefore aren't called. I dont know if this happens on ATI and Nvidia or just Nvidia at this point.

 

Edit:

 

I fixed the problem now, I was not using the gluniform commands correctly.


Edited by harshman_chris, 22 January 2013 - 07:11 PM.





Old topic!
Guest, the last post of this topic is over 60 days old and at this point you may not reply in this topic. If you wish to continue this conversation start a new topic.



PARTNERS