Jump to content

  • Log In with Google      Sign In   
  • Create Account


Multi-material texture?


Old topic!
Guest, the last post of this topic is over 60 days old and at this point you may not reply in this topic. If you wish to continue this conversation start a new topic.

  • You cannot reply to this topic
9 replies to this topic

#1 Hawkblood   Members   -  Reputation: 723

Like
0Likes
Like

Posted 19 February 2014 - 11:25 AM

Is it possible to have a single texture on an object with some areas shinny and some dull? Basically, I want to render a sphere for a planet and have the water to be shinny (specular) and the land to be dull. If this is not possible, what approaches would work fast with good quality?

Sponsor:

#2 L. Spiro   Crossbones+   -  Reputation: 13201

Like
2Likes
Like

Posted 19 February 2014 - 12:00 PM

Use a specular map or treat the texture’s alpha as being specular.


L. Spiro

Edited by L. Spiro, 19 February 2014 - 12:00 PM.

It is amazing how often people try to be unique, and yet they are always trying to make others be like them. - L. Spiro 2011
I spent most of my life learning the courage it takes to go out and get what I want. Now that I have it, I am not sure exactly what it is that I want. - L. Spiro 2013
I went to my local Subway once to find some guy yelling at the staff. When someone finally came to take my order and asked, “May I help you?”, I replied, “Yeah, I’ll have one asshole to go.”
L. Spiro Engine: http://lspiroengine.com
L. Spiro Engine Forums: http://lspiroengine.com/forums

#3 Hawkblood   Members   -  Reputation: 723

Like
0Likes
Like

Posted 19 February 2014 - 12:12 PM

I like the idea of using the alpha channel as specular.... How? Is it a texture stage state?

#4 L. Spiro   Crossbones+   -  Reputation: 13201

Like
2Likes
Like

Posted 19 February 2014 - 12:39 PM

Sample the texture in the shader and use the value.w (or value.a) in your specular lighting equation.


L. Spiro
It is amazing how often people try to be unique, and yet they are always trying to make others be like them. - L. Spiro 2011
I spent most of my life learning the courage it takes to go out and get what I want. Now that I have it, I am not sure exactly what it is that I want. - L. Spiro 2013
I went to my local Subway once to find some guy yelling at the staff. When someone finally came to take my order and asked, “May I help you?”, I replied, “Yeah, I’ll have one asshole to go.”
L. Spiro Engine: http://lspiroengine.com
L. Spiro Engine Forums: http://lspiroengine.com/forums

#5 cgrant   Members   -  Reputation: 597

Like
1Likes
Like

Posted 19 February 2014 - 12:47 PM

The alpha channel is just an additional channel in the actual texture/texture data...texture state/texture stage state is a separate issue. Just add an alpha channel to the single texture you proprosed and in the shader use that channel for the specular calculation..



#6 Hawkblood   Members   -  Reputation: 723

Like
0Likes
Like

Posted 19 February 2014 - 05:57 PM


Sample the texture in the shader and use the value.w (or value.a) in your specular lighting equation.

I would need to modify or completely change the shader, but I think that's the best approach.

 

 

 

 

EDIT: Can someone point out *how* to use the above mentioned value.w (or value.a) in this effect file:

//-----------------------------------------------------------------------------
// Copyright (c) 2008 dhpoware. All Rights Reserved.
//
// Permission is hereby granted, free of charge, to any person obtaining a
// copy of this software and associated documentation files (the "Software"),
// to deal in the Software without restriction, including without limitation
// the rights to use, copy, modify, merge, publish, distribute, sublicense,
// and/or sell copies of the Software, and to permit persons to whom the
// Software is furnished to do so, subject to the following conditions:
//
// The above copyright notice and this permission notice shall be included in
// all copies or substantial portions of the Software.
//
// THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
// OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
// FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
// AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
// LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
// FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
// IN THE SOFTWARE.
//-----------------------------------------------------------------------------
//
// Tangent space normal mapping with multiple point lights in a single pass
// using shader model 3.0. This effect file limits the number of point lights
// to 8.
//
//
//
//*************** THIS HAS BEEN MODIFIED TO SUPPORT 3 TYPES OF LIGHTS WITHIN 
//					THE SAME EFFECT
//
//
//-----------------------------------------------------------------------------

#define MAX_ALL_LIGHTS 16

struct AllLight
{
	int type;//0==directional, 1==point, 2==spot
	float3 dir;
	float3 pos;				// world space position
	float4 ambient;
	float4 diffuse;
	float4 specular;
	float spotInnerCone;	// spot light inner cone (theta) angle
	float spotOuterCone;	// spot light outer cone (phi) angle
	float radius;
};

struct Material
{
	float4 ambient;
	float4 diffuse;
	float4 emissive;
	float4 specular;
	float shininess;
};

//-----------------------------------------------------------------------------
// Globals.
//-----------------------------------------------------------------------------

float4x4 worldMatrix;
float4x4 worldInverseTransposeMatrix;
float4x4 worldViewProjectionMatrix;

float3 cameraPos;
float4 globalAmbient;
int numLights;

AllLight lights[MAX_ALL_LIGHTS];
Material material;

//-----------------------------------------------------------------------------
// Textures.
//-----------------------------------------------------------------------------

texture colorMapTexture;
texture normalMapTexture;

sampler2D colorMap = sampler_state
{
	Texture = <colorMapTexture>;
    MagFilter = Linear;
    MinFilter = Anisotropic;
    MipFilter = Linear;
    MaxAnisotropy = 16;
};

sampler2D normalMap = sampler_state
{
    Texture = <normalMapTexture>;
    MagFilter = Linear;
    MinFilter = Anisotropic;
    MipFilter = Linear;
    MaxAnisotropy = 16;
};

//-----------------------------------------------------------------------------
// Vertex Shaders.
//-----------------------------------------------------------------------------

struct VS_INPUT
{
	float3 position : POSITION;
	float2 texCoord : TEXCOORD0;
	float3 normal : NORMAL;
    float4 tangent : TANGENT;
};

struct VS_OUTPUT
{
	float4 position : POSITION;
	float3 worldPos : TEXCOORD0;
	float2 texCoord : TEXCOORD1;
	float3 normal : TEXCOORD2;
	float3 tangent : TEXCOORD3;
	float3 bitangent : TEXCOORD4;
};


VS_OUTPUT VS_AllLighting(VS_INPUT IN)
{
	VS_OUTPUT OUT;

	OUT.position = mul(float4(IN.position, 1.0f), worldViewProjectionMatrix);
	OUT.worldPos = mul(float4(IN.position, 1.0f), worldMatrix).xyz;
	OUT.texCoord = IN.texCoord;
	
	OUT.normal = mul(IN.normal, (float3x3)worldInverseTransposeMatrix);
	OUT.tangent = mul(IN.tangent.xyz, (float3x3)worldInverseTransposeMatrix);
	OUT.bitangent = cross(OUT.normal, OUT.tangent) * IN.tangent.w;


	return OUT;
}

//-----------------------------------------------------------------------------
// Pixel Shaders.
//-----------------------------------------------------------------------------

float4 PS_AllLighting(VS_OUTPUT IN) : COLOR
{

    float3 t = normalize(IN.tangent);
    float3 b = normalize(IN.bitangent);
    float3 n = normalize(IN.normal);

    float3x3 tbnMatrix = float3x3(t.x, b.x, n.x,
	                              t.y, b.y, n.y,
	                              t.z, b.z, n.z);
	                                 
    float3 v = normalize(mul(cameraPos - IN.worldPos, tbnMatrix));
    float3 l = float3(0.0f, 0.0f, 0.0f);
    float3 h = float3(0.0f, 0.0f, 0.0f);
    
    float atten = 0.0f;
    float nDotL = 0.0f;
    float nDotH = 0.0f;
    float power = 0.0f;
    
    float4 color = float4(0.0f, 0.0f, 0.0f, 0.0f);
    
    n = normalize(tex2D(normalMap, IN.texCoord).rgb * 2.0f - 1.0f);

	for (int i = 0; i < numLights; ++i)
    {
		float len=length(lights[i].pos - IN.worldPos);
		if (len<lights[i].radius*1.25f){
			if (lights[i].type==0){
				l=mul(-lights[i].dir,tbnMatrix);
				atten = 1.0f;
			}
			else{
				l = mul((lights[i].pos - IN.worldPos) / lights[i].radius, tbnMatrix);
			   atten = saturate(1.0f - dot(l, l));
			}
			l = normalize(l);
			if (lights[i].type==2) {
				float2 cosAngles = cos(float2(lights[i].spotOuterCone, lights[i].spotInnerCone) * 0.5f);
				float3 dl=mul(lights[i].dir,tbnMatrix);
				float spotDot = dot(-l, normalize(dl));
				float spotEffect = smoothstep(cosAngles[0], cosAngles[1], spotDot);
    
				atten *= spotEffect;
			}      
			h = normalize(l + v);
        
			nDotL = saturate(dot(n, l));
			nDotH = saturate(dot(n, h));
			power = (nDotL == 0.0f) ? 0.0f : pow(nDotH, material.shininess);
        
			color += ((material.diffuse * lights[i].diffuse )+
				(lights[i].specular * power ))* atten;

		}
    }
     color += material.ambient * globalAmbient +material.emissive; 

	 return color * tex2D(colorMap, IN.texCoord);
}



//-----------------------------------------------------------------------------
// Techniques.
//-----------------------------------------------------------------------------

technique NormalMappingAllLighting
{
    pass
    {
        VertexShader = compile vs_3_0 VS_AllLighting();
        PixelShader = compile ps_3_0 PS_AllLighting();
    }
}



Edited by Hawkblood, 19 February 2014 - 06:28 PM.


#7 Hawkblood   Members   -  Reputation: 723

Like
0Likes
Like

Posted 21 February 2014 - 08:16 AM

Seriously. I would like some help with this.

#8 haegarr   Crossbones+   -  Reputation: 4155

Like
0Likes
Like

Posted 21 February 2014 - 09:31 AM

From the shader code snippet I would say that you have to replace the so long object fix value material.shininess in this line

power = (nDotL == 0.0f) ? 0.0f : pow(nDotH, material.shininess);

with the value sampled from the texture. You may need to adapt the value range to match what you usually pass in material.shininess.

 

BTW: You may be interested in texture layering; here is a thread with some useful informations. It is, so to say, the generalization of the above, so that you are not only able to work with differing parameters but with differing shading formulas as well.



#9 TheComet   Members   -  Reputation: 1480

Like
1Likes
Like

Posted 21 February 2014 - 10:33 AM

Something like this will do it:

//-----------------------------------------------------------------------------
// Pixel Shaders.
//-----------------------------------------------------------------------------

float4 PS_AllLighting(VS_OUTPUT IN) : COLOR
{

float3 t = normalize(IN.tangent);
float3 b = normalize(IN.bitangent);
float3 n = normalize(IN.normal);

float3x3 tbnMatrix = float3x3(t.x, b.x, n.x,
     t.y, b.y, n.y,
     t.z, b.z, n.z);
    
float3 v = normalize(mul(cameraPos - IN.worldPos, tbnMatrix));
float3 l = float3(0.0f, 0.0f, 0.0f);
float3 h = float3(0.0f, 0.0f, 0.0f);

float atten = 0.0f;
float nDotL = 0.0f;
float nDotH = 0.0f;
float power = 0.0f;

float4 color = float4(0.0f, 0.0f, 0.0f, 0.0f);

n = normalize(tex2D(normalMap, IN.texCoord).rgb * 2.0f - 1.0f);

    // sample color map
   float4 colorMap = tex2D(colorMap, IN.texCoord);  // TC Edit

    for (int i = 0; i < numLights; ++i)
{
        float len=length(lights[i].pos - IN.worldPos);
        if (len<lights[i].radius*1.25f){
            if (lights[i].type==0){
                l=mul(-lights[i].dir,tbnMatrix);
                atten = 1.0f;
            }
            else{
                l = mul((lights[i].pos - IN.worldPos) / lights[i].radius, tbnMatrix);
             atten = saturate(1.0f - dot(l, l));
            }
            l = normalize(l);
            if (lights[i].type==2) {
                float2 cosAngles = cos(float2(lights[i].spotOuterCone, lights[i].spotInnerCone) * 0.5f);
                float3 dl=mul(lights[i].dir,tbnMatrix);
                float spotDot = dot(-l, normalize(dl));
                float spotEffect = smoothstep(cosAngles[0], cosAngles[1], spotDot);

                atten *= spotEffect;
            }
            h = normalize(l + v);

            nDotL = saturate(dot(n, l));
            nDotH = saturate(dot(n, h));
            power = (nDotL == 0.0f) ? 0.0f : pow(nDotH, material.shininess * colorMap.w);  // TC Edit

            color += ((material.diffuse * lights[i].diffuse )+
                (lights[i].specular * power ))* atten;

        }
}
color += material.ambient * globalAmbient +material.emissive;

     return color * colorMap;  // TC Edit
}

An alpha value of 0.0 means no specular lighting, an alpha value of 1.0 means full specular lighting.

 

You *might* have to change this:

return color * colorMap;

To the following,

return color * float4(colorMap.xyz, 1.0f);

if the render target makes use of the alpha channel.


Edited by TheComet, 21 February 2014 - 10:35 AM.

YOUR_OPINION >/dev/null


#10 Hawkblood   Members   -  Reputation: 723

Like
0Likes
Like

Posted 21 February 2014 - 12:39 PM

My render target makes use of the alpha channel with the color map so I will be using the .w from the normalMap. I also changed the "colorMap" to avoid conflicts with the actual "colorMap" texture. Here is the modified code:

float4 PS_AllLighting(VS_OUTPUT IN) : COLOR
{

    float3 t = normalize(IN.tangent);
    float3 b = normalize(IN.bitangent);
    float3 n = normalize(IN.normal);

    float3x3 tbnMatrix = float3x3(t.x, b.x, n.x,
	                              t.y, b.y, n.y,
	                              t.z, b.z, n.z);
	                                 
    float3 v = normalize(mul(cameraPos - IN.worldPos, tbnMatrix));
    float3 l = float3(0.0f, 0.0f, 0.0f);
    float3 h = float3(0.0f, 0.0f, 0.0f);
    
    float atten = 0.0f;
    float nDotL = 0.0f;
    float nDotH = 0.0f;
    float power = 0.0f;
    
    float4 color = float4(0.0f, 0.0f, 0.0f, 0.0f);
    
    n = normalize(tex2D(normalMap, IN.texCoord).rgb * 2.0f - 1.0f);
	float4 ShinnyMap = tex2D(normalMap, IN.texCoord);  // TC Edit

	for (int i = 0; i < numLights; ++i)
    {
		float len=length(lights[i].pos - IN.worldPos);
		if (len<lights[i].radius*1.25f){
			if (lights[i].type==0){
				l=mul(-lights[i].dir,tbnMatrix);
				atten = 1.0f;
			}
			else{
				l = mul((lights[i].pos - IN.worldPos) / lights[i].radius, tbnMatrix);
			   atten = saturate(1.0f - dot(l, l));
			}
			l = normalize(l);
			if (lights[i].type==2) {
				float2 cosAngles = cos(float2(lights[i].spotOuterCone, lights[i].spotInnerCone) * 0.5f);
				float3 dl=mul(lights[i].dir,tbnMatrix);
				float spotDot = dot(-l, normalize(dl));
				float spotEffect = smoothstep(cosAngles[0], cosAngles[1], spotDot);
    
				atten *= spotEffect;
			}      
			h = normalize(l + v);
        
			nDotL = saturate(dot(n, l));
			nDotH = saturate(dot(n, h));
			power = (nDotL == 0.0f) ? 0.0f : pow(nDotH, material.shininess*ShinnyMap.w);
        
			color += ((material.diffuse * lights[i].diffuse )+
				(lights[i].specular * power ))* atten;

		}
    }
     color += material.ambient * globalAmbient +material.emissive; 

	 return color * tex2D(colorMap, IN.texCoord);
}

EDIT: It works. I had posted that it doesn't, but I was not rendering with the modified textures. It works now. Thanks!

 

Here is the normal map I'm using. The "white" spots are alpha==0.

Attached Thumbnails

  • shipIntNorm02.png

Edited by Hawkblood, 21 February 2014 - 12:54 PM.





Old topic!
Guest, the last post of this topic is over 60 days old and at this point you may not reply in this topic. If you wish to continue this conversation start a new topic.



PARTNERS