Jump to content

  • Log In with Google      Sign In   
  • Create Account

Eliminating OpenGL/DirectX differences


Old topic!
Guest, the last post of this topic is over 60 days old and at this point you may not reply in this topic. If you wish to continue this conversation start a new topic.

  • You cannot reply to this topic
11 replies to this topic

#1 Juliean   GDNet+   -  Reputation: 2731

Like
0Likes
Like

Posted 06 April 2014 - 06:33 AM

Hello,

 

I've writting myself a graphical wrapper for writing API independant code, also including a basic unified shading language. For 90% of the times this works well without any kind of modification, but then there are times when I'm just having such trouble getting stuff to work under OpenGL4. My entry-point, if you will, is always DirectX11, because I'm far more common to it, and so are my coordinate systems (LH).

 

Now most of my problems are due to matrix multiplications. First thing I did was flip the multiplication order when parsing out GLSL shader code. I also flipped the sign of the m22-value in the projection-matrices to resolve a problem where everything was rendered upside down.

Matrix MatPerspFovLH(float fovy, float aspect, float zn, float zf)
{
    float yScale = cotan(fovy/2.0f);
    float xScale = yScale / aspect;

    return Matrix(    xScale, 0.0f,    0.0f,            0.0f,
#ifdef ACL_API_GL4
                    0.0f,    -yScale,    0.0f,            0.0f,
#else
                    0.0f,    yScale,    0.0f,            0.0f,
#endif
                    0.0f,    0.0f,    zf/(zf-zn),        1.0,
                    0.0f,    0.0f,    -zn*zf/(zf-zn),    0.0f);
}

However, this was a total quess (I'm still quite surprised it works), and there are still occasional problems, like right now I'm trying to solve a complete f***-up in my cascaded shadow maps in opengl.

 

The question now mainly is: Is there any way, like some sort of setting, to make matrix multiplication, screen space etc... compatible to DirectX in OpenGL (or vice versa, for all I care), without having to "manually" adjust multiplication order and tampering with the matrix values? I'm also hoping that those issues will go away once that works, so well...



Sponsor:

#2 haegarr   Crossbones+   -  Reputation: 4588

Like
0Likes
Like

Posted 06 April 2014 - 10:05 AM

I'm not 100% sure, but ...

 

1.) OpenGL 4 is used to work with column vectors and matrices in row major order. D3D11 is used to work with row vectors and matrices in column major order. In memory this makes the same sequence of numbers.

 

  EDIT: So, after some more research … HLSL assumes column-major order at default, and GLSL assumes column-major order, too. Just D3D9 FFP and DirectXMath use row-major layout.

 

2.) Using shaders give you the freedom to choose between A * B and B * A like you need. You can use column / row vectors in both HLSL and GLSL. 

 

3.) If you want to use LH co-ordinate system with OpenGL, the only thing you need to do is a scaling S(1,1,-1) placed between the projection matrix and the view matrix. Because the projection matrix is different anyway, you can include the mirroring into the projection matrix used for OpenGL, like so when using row vectors:

     V * ( S(1,1,-1) * PGL )

 

4.) The fact that you need to negate m22 of the projection matrix … seems me strange. I assume that there is a mistake somewhere.

 

  EDIT: After some research: The reason is in the window origin problem.


Edited by haegarr, 09 April 2014 - 07:36 AM.


#3 imoogiBG   Members   -  Reputation: 1247

Like
5Likes
Like

Posted 06 April 2014 - 12:32 PM

You can use whatever you want with both D3D/OGL. There is no limitation any combination.
In both you can:

 

1 - Change the matrix layout(row/column major)

2 - Mat * Vec/Vec * Mat depends ONLY on your math library.

3 - There is no such a thing "LEFT/RIGHT hand coord system" for the hardware. You can use any coord sys. 

 

How to change the data layout :

 

For OGL - search for layout (row_major)

For D3D - #pragma pack_matrix( row_major ) or pass D3DCOMPILE_PACK_MATRIX_ROW_MAJOR to D3DCompile



#4 haegarr   Crossbones+   -  Reputation: 4588

Like
1Likes
Like

Posted 06 April 2014 - 03:03 PM

I'm interested in what is wrong with my previous answer. It would be nice if you can clarify this...

 

1 - Change the matrix layout(row/column major)

IMHO I have not said something contradicting this. However, the freedom is not without costs. With the input registers of the GPU being exactly 4 elements wide, it is most efficient if the columns / rows of a matrix passed into the GPU are 4 elements wide. This is no problem with a 4 by 4 matrix, obviously, but it matters if one passes 4 by 3 matrices (as is sufficient for affine transformations because the remaining row / column is constant; the most obvious use case is GPU based skinning).

 

Within an application that was implemented following OpenGL's historical conventions, a 4 column by 3 row matrix in column major order nevertheless requires 4 input registers although only 12 elements are actually used. Analogously are things with D3D's historical conventions. Hence the conventions of both OpenGL and D3D were changed (I'm still speaking of a convention but not a constrained). Fortunately both changes are so that the absolute sequence of values is again the same for both OpenGL and D3D. So passing them by cbuffer / UBOs makes no difference, assuming the expected layout is used. That's what my point 1.) in the above answer is about. 

 

2 - Mat * Vec/Vec * Mat depends ONLY on your math library.
I mentioned in point 2.) that both products can be computed in shaders, too.
 
BTW: It is not totally true that the order depends only on the math library. With the layout parametrization of matrices one can pass in matrices so that they work as being transposed. Because GPUs do not distinguish between N by 1 and 1 by N vectors, it is sufficient to transpose the matrix if one wants to reverse the order of matrix products inside the shader. So the order of multiplication depends on both how matrices are provided by the math library and how they are passed into the shader.

 

3 - There is no such a thing "LEFT/RIGHT hand coord system" for the hardware. You can use any coord sys. 

Yes, you can, but you need to take care that camera-space coordinates are transformed into the intended clip-space coordinates (which differ between D3D and OpenGL). You do this by defining an appropriate projection matrix. The projections for a LH and a RH co-ordinate system will differ. With the well known standard projection matrix PGL of OpenGL in mind, applying a mirroring onto the z axis yields in the corresponding LH matrix. That's what my point 3.) in the above answer is about. Is there a mistake in this reasoning?

 

 

@OP:

There is a sample book chapter The ANGLE Project: Implementing OpenGL ES 2.0 on Direct3D (PDF) that deals with OpenGL ES 2.0 being implemented on top of Direct3D 9. That is not exactly what you are after, but perhaps some of the things mentioned there may be of interest for you. Two aspects that came to my mind are the different clip spaces and the different window co-ordinates, both of which are investigated in the book chapter. Hope that helps.


Edited by haegarr, 07 April 2014 - 12:36 AM.


#5 jariRG   Members   -  Reputation: 755

Like
2Likes
Like

Posted 07 April 2014 - 12:10 PM

There was a really well written article about this subject:

http://www.gamedev.net/page/resources/_/technical/graphics-programming-and-theory/perspective-projections-in-lh-and-rh-systems-r3598



#6 Juliean   GDNet+   -  Reputation: 2731

Like
0Likes
Like

Posted 08 April 2014 - 12:13 PM

Thanks you for the input,

 

I have since further investigated the problem, but first some heads up. My matrices are already in row major ordering, I have already explicitely set that in DirectX11, and OpenGL seems to be able to work with it. Furthermore, the multiplication inversion still has to happen for some reason, otherwise I a funny looking vertex soup. I belive this is due to the fact that I multiply my viewprojection-matrix with the world-matrix in shader:

out.vPos = mul(in.vPos, mul(mWorld, mViewProj));

// translates to this in GLSL:
out.vPos = (mViewProj * mWorld) * in.vPos;

I really don't have any clue why this is necessary though, since I'm using row major ordering in both cases. Any ideas whats the reason behind this?

 

Furthermore, the reason why the m22-invert was working and I would get upside-down geometry otherwise is actually pretty simple: I didn't flip the vertical texture coordinate in my sprite class, which resulted in the final result of all my renderings to be upside down. I didn't really look that much into it in the first place, but that was also the reason why I had (almost) no problems with triangle winding order, the manual flipping of the geometry in the view-matrix also changed the triangulation. I now flipped the vertical texture-coordinates in the sprite, removed the view-matrix-manipulation, and switched the cull-order in respect when using OpenGL4. This now produces the same visual result as bevor, minus the culling-order problem in my water, which is definately a plus.

 

Still, this leaves me with even more problems...

 

So as I mentioned I had to flip the texture coordinate in the sprite class. I already did that before for my fullscreen-quads, it is necessary for them to render correctly in OpenGL. Why? I belive this is the main reason for all the problems I have left (CSM still doesn't work, water-reflections go all ape-s***). I think I have heard something that OpenGL stores the textures in a different way then direct-x (upside down, if I am correct), but why do I have to change the texture-coordintes to reflect this? And is there something I can do to combat this, except manually flipping the texture coordinates wherever they are used (which is really a pain, especially when they are e.g. calculated directly in the shader), maybe something that tells OpenGL to change its texture storage or something like that?

 

Here is what I mean, the fullscreen quad with the changes I had to make for OpenGL (first two floats are position in screen space, last two texture coordinates):

// DirectX
const SCREEN_QUADVERTEX quadVertices[] =
{
    { -1.0f, 1.0f, 0.0f, 0.0f },
    { 1.0f, 1.0f, 1.0f, 0.0f },
    { 1.0f, -1.0f, 1.0f, 1.0f },
    { -1.0f, -1.0f, 0.0f, 1.0f }
};

// OpenGL:
const SCREEN_QUADVERTEX quadVertices[] =
{
	{ -1.0f, -1.0f, 0.0f, 0.0f },
	{ 1.0f, -1.0f, 1.0f, 0.0f },
	{ 1.0f, 1.0f, 1.0f, 1.0f },
	{ -1.0f, 1.0f, 0.0f, 1.0f }
};

Any ideas?



#7 L. Spiro   Crossbones+   -  Reputation: 14267

Like
1Likes
Like

Posted 08 April 2014 - 06:55 PM

However, this was a total quess (I'm still quite surprised it works), and there are still occasional problems, like right now I'm trying to solve a complete f***-up in my cascaded shadow maps in opengl.

Probably because OpenGL normalizes to the depth range -1 to 1 whereas Direct3D uses NDC’s from 0 to 1.
Not only does this mess up shadows, you are likely only using half the range of the depth buffer with the way you are creating your projection matrix.


L. Spiro
It is amazing how often people try to be unique, and yet they are always trying to make others be like them. - L. Spiro 2011
I spent most of my life learning the courage it takes to go out and get what I want. Now that I have it, I am not sure exactly what it is that I want. - L. Spiro 2013
I went to my local Subway once to find some guy yelling at the staff. When someone finally came to take my order and asked, “May I help you?”, I replied, “Yeah, I’ll have one asshole to go.”
L. Spiro Engine: http://lspiroengine.com
L. Spiro Engine Forums: http://lspiroengine.com/forums

#8 Hodgman   Moderators   -  Reputation: 31851

Like
4Likes
Like

Posted 08 April 2014 - 10:31 PM

Thanks you for the input,
 
I have since further investigated the problem, but first some heads up. My matrices are already in row major ordering, I have already explicitely set that in DirectX11, and OpenGL seems to be able to work with it. Furthermore, the multiplication inversion still has to happen for some reason, otherwise I a funny looking vertex soup. I belive this is due to the fact that I multiply my viewprojection-matrix with the world-matrix in shader:

out.vPos = mul(in.vPos, mul(mWorld, mViewProj));

// translates to this in GLSL:
out.vPos = (mViewProj * mWorld) * in.vPos;
I really don't have any clue why this is necessary though, since I'm using row major ordering in both cases. Any ideas whats the reason behind this?

 

I'd really avoid having this difference if I was you. There's no reason that you have to use one multiplication order in D3D and the opposite in GL. It will be a lot easier if you just use the same conventions in both APIs.

When multiplying a 4x4 matrix and a vector 4, you're actually treating the vector as a matrix. You've got a choice whether you treat it as a 4x1 or a 1x4 matrix. When multiplying matrices, the inner values have to match (num columns of lhs and num rows of rhs have to match).
This means that if you treat the vector as a 4x1 matrix (4-rows, 1-column, AKA a "column vector") then it must appear on the right of the matrix, and that if you treat it as a 1x4 (1-row, 4-columns, AKA a "row vector") then it must appear on the left of the matrix.
i.e.
4x4 * 4x1 < valid
1x4 * 4x1 < valid
4x4 * 1x4 < invalid / can't be done
4x1 * 4x1 < invalid / can't be done

GLSL and HLSL do this automatically - if you put your vector on the right of a matrix, you're using the column-vector convention / if you put your vector on the left of the matrix, you're using the row-vector convention.

So, as you can see from your code, you're using column-vectors in GL and row-vectors in D3D.
This is a huge problem, because the correct way to construct a transformation matrix differs depending on this convention.
If you're using the column-vector convention, your matrices look like this:

|xx yx zx tx|   |vx|
|xy yy zy ty| * |vy|
|xz yz zz yz|   |vz|
| 0  0  0  1|   | 1|

And if you're using the row-vector convention, your matrices look like this:

               |xx xy xz  0|
|vx vy vz 1| * |yx yy yz  0|
               |zx zy zz  0|
               |tx ty tz  1|

i.e. if you're using the row-vector convention, you store your basis vectors and translation in the rows of the matrix. If you're using the column-vector convention, you store your basis vectors in the columns of the matrix.

Each convention also uses the opposite matrix concatenation order than the other.
Row-vector convention uses result = vector * local * global, column-vector convention uses result = global * local * vector.
 
Are you using the same math library across both APIs? Or are you for example using D3DX for D3D and GLM for GL?
If you are, then it's possible that each of these libraries is constructing matrices using the opposite convention to the other.
 
A column-vector convention matrix, stored in column-major order looks like:
  xx, xy, xz, 0, yx, yy, yz, 0, zx, zy, zz, 0, tx, ty, tz, 1
A column-vector convention matrix, stored in row-major order looks like:
  xx, yx, zx, tx, xy, yy, zy, ty, xz, yz, zz, tz, 0, 0, 0, 1
A row-vector convention matrix, stored in column-major order looks like:
  xx, yx, zx, tx, xy, yy, zy, ty, xz, yz, zz, tz, 0, 0, 0, 1
A row-vector convention matrix, stored in row-major order looks like:
  xx, xy, xz, 0, yx, yy, yz, 0, zx, zy, zz, 0, tx, ty, tz, 1

 

So as well as making sure you're using both row-major or both-column major in both D3D and GL, you also need to make sure that your math libraries are both following the column-vector convention or the row-vector convention. If you do that, then the shader code and matrix multiplication order will be exactly the same across both APIs.



#9 Juliean   GDNet+   -  Reputation: 2731

Like
0Likes
Like

Posted 09 April 2014 - 03:02 AM


Probably because OpenGL normalizes to the depth range -1 to 1 whereas Direct3D uses NDC’s from 0 to 1.
Not only does this mess up shadows, you are likely only using half the range of the depth buffer with the way you are creating your projection matrix.

 

Thats surely a problem I'll tackle soon, but it isn't what causes this. I was right, it is the same thing with the texture coordinates. In the cascaded shadow map shader, the texture coordinates are calculated by multiplying the position with the light view matrix. The depth is then sampled from the depth-map (all cascades in one):

float depth = SampleLOD(Shadow, 
	float2( 
		vShadowTexCoord.x + (float(x) * vBorderPadding.w) , // w => native texel size 
		vShadowTexCoord.y + (float(y) * vBorderPadding.x) // x => texelsize 
		), 0);

Inverting the y-coordinate does the trick again:

float depth = SampleLOD(Shadow, 
	float2( 
		vShadowTexCoord.x + (float(x) * vBorderPadding.w) , // w => native texel size 
		1.0f - (vShadowTexCoord.y + (float(y) * vBorderPadding.x)) // x => texelsize 
		), 0);

This is really everywhere, thats also the reason I had to reverse the texture coordinates manually in the application for the fullscreen-quad and the sprite. I also mirrored the textures from the filesystem when loading them with FreeImage, which makes normal model texcoordinates work. Now, is there any way to solve this? The only thing I can think of is parsing all Sample-functions to

Sample(float2(vTex.x + vTex.x, 1.0f) - vTex));

in OpenGL, which would write out to sampling from (vTex.x, 1.0f - vTex.y), but it comes down to more work in the shader, especially when the texcoordintes are declared like in my sample directly in the function. Any other ideas?

 


So as well as making sure you're using both row-major or both-column major in both D3D and GL, you also need to make sure that your math libraries are both following the column-vector convention or the row-vector convention. If you do that, then the shader code and matrix multiplication order will be exactly the same across both APIs.

 

Thats really strange, I am using the same (namely my own) math libary for both DX and OpenGL, as you can see in my first post ;)

It appears though, that my OpenGL defaults to column_major, since setting my uniform-blocks to

layout(row_major) unifom Stage
{
     mat4 mViewProj;
}

and reversing the mul-order to normal (as in DX), now at least renders SOMETHING, however its still far from correct. Now my sky is rendering sort of like a tube when looking down the x-axis and otherwise isn't at all (I can't show a screenshot since OpenGL doesn't let me). Thats the vertex-shader:

		out.vPos = float4(in.vPos, 1.0f);
			
		matrix mModWorld = mWorld;
		mModWorld[3].xyz = vCameraPos;
		
		matrix mWorldView = mul(mModWorld, mView);
		float3 vVertex = mul(out.vPos, mWorldView).xyz;
		
		out.vPos = mul(out.vPos, mul(mModWorld, mViewProj)).xyww;
		out.vPos.z *= 0.99999f;

The other models render mostly correct, except the skinned one. Sadly I can't show you too, but while the overall animation look is still correct, the individual triangles go all over the place - it looks kind of spiky. Heres that vertex shader:

float4 pos = float4(0.0f, 0.0f, 0.0f, 1.0f);
float3 norm = float3(0.0f, 0.0f, 0.0f);
float lastWeight = 0.0f;
int n = 1; // TODO: read in
float4 inPos = float4(in.vPos, 1.0f);
float4 vNormal = float4(normalize(in.vNrm), 1.0f);

//Blend vertex position & normal
for(int i = 0; i < n; ++i)
{
	lastWeight += in.vWeights[i];
	pos += in.vWeights[i] * mul(inPos, mPalette[int(in.vIndices[i])]);
	norm += in.vWeights[i] * mul(vNormal, mPalette[int(in.vIndices[i])]).xyz;
}
lastWeight = 1.0f - lastWeight;

pos += mul(inPos, mPalette[int(in.vIndices[n])]) * lastWeight;
norm += mul(vNormal, mPalette[int(in.vIndices[n])]).xyz * lastWeight;
pos.w = 1.0f;

out.vPos1 = mul(pos, mWorld);
out.vPos = mul(out.vPos1, mViewProj);

out.vNormal = normalize(mul(float4(normalize(norm), 0.0f), mWorld).xyz);

out.vTex0 = in.vTex0;

I mean, now that matrix layout, multiplication order, and the way that matrices are handled/passed in by the application are all equal, do you see anything (perhaps in those shaders) that can cause such strange behaviour?



#10 Hodgman   Moderators   -  Reputation: 31851

Like
1Likes
Like

Posted 09 April 2014 - 06:01 AM

D3D shaders (HLSL) use column-major storage by default as well, just like GLSL. You've got to use "row_major float4x4 myMat;" or the options posted by imoogiBG above. Are you doing this in your working HLSL version?
 
What's the multiply with 0.99999f for - to make sure the sky never touches the far plane?
The vVertex variable in that code doesn't get used, is that right?
 
In the second code block, vNormal should have a w value of zero -- otherwise your normals will be affected by the translation row of the mPalette matrix!
Seeing that n is hard-coded to 1 for now, I'd simplify that shader as much as possible, just to reduce the amount of things that could be going wrong.

float4 inPos = float4(in.vPos, 1.0);
float4 vNormal = float4(in.vNrm, 0.0);
float3 pos = in.vWeights.x * mul(inPos, mPalette[int(in.vIndices.x)]).xyz;
float3 norm = in.vWeights.x * mul(vNormal, mPalette[int(in.vIndices.x)]).xyz;
out.vPos_ws = mul(float4(pos,1.0), mWorld);
out.vPos = mul(float4(out.vPos_ws.xyz,1.0), mViewProj);
out.vNormal = mul(float4(norm, 0.0f), mWorld).xyz;//normalize in the pixel shader
out.vTex0 = in.vTex0;

I haven't used GL for a while... is it possible that somehow when you update your uniform object / send the matrices to the shader, that the GL driver is somehow transposing them or modifying them in some way?



#11 haegarr   Crossbones+   -  Reputation: 4588

Like
1Likes
Like

Posted 09 April 2014 - 06:13 AM


...

This is really everywhere, thats also the reason I had to reverse the texture coordinates manually in the application for the fullscreen-quad and the sprite. I also mirrored the textures from the filesystem when loading them with FreeImage, which makes normal model texcoordinates work. Now, is there any way to solve this? ...

I assume you suffer from the window co-ordinate problem: The book excerpt (I already mentioned it above) tells this with the "present transform" in eq. 39.1 and 39.2 and the following explanation "Window Origin". It mentions three ways to overcome it, all with some kind of drawback, of course.



#12 Juliean   GDNet+   -  Reputation: 2731

Like
0Likes
Like

Posted 09 April 2014 - 06:23 AM


D3D shaders (HLSL) use column-major storage by default as well, just like GLSL. You've got to use "row_major float4x4 myMat;" or the options posted by imoogiBG above. Are you doing this in your working HLSL version?

 

Yes, I have

#pragma pack_matrix( row_major )

at the top of all of my shaders.

 


What's the multiply with 0.99999f for - to make sure the sky never touches the far plane?

 

Yep, thats what its for. I get heavy z-fighting unless for that line.

 


The vVertex variable in that code doesn't get used, is that right?

 

Well, that gets used later on for atmospheric scattering calculation, but nothing that affects the vertex position at all.

 


In the second code block, vNormal should have a w value of zero -- otherwise your normals will be affected by the translation row of the mPalette matrix!

 

Oh, I already wondered why my lighting on that model was off. I'm sure I checked that though, very weird. Thanks anyways, crosses another thing off the list :D

 


I haven't used GL for a while... is it possible that somehow when you update your uniform object / send the matrices to the shader, that the GL driver is somehow transposing them or modifying them in some way?

 

Thats very unlikely, since I'm using uniform buffers, and I'm uploading the data arbitrarily - or is there something that OpenGL does by itself that might change odering here?

 


I assume you suffer from the window co-ordinate problem: The book excerpt (I already mentioned it above) tells this with the "present transform" in eq. 39.1 and 39.2 and the following explanation "Window Origin". It mentions three ways to overcome it, all with some kind of drawback, of course.

 

Yes, you are totally right, thats the problem, at least with the reading in shader. I partially-countered this at first by inverting the coordinates for the fullscreen-pass, but that left me with even more problems. I'm now using step 2 by inverting the y-texture coordinate in shader, also I have to adjust the CPU-access of textures to account for the fact that textures are now stored upside down in regards.

 

Now all thats left is the vertex-transform problem, technically it is working with the old setting of reversing the multiplication order, but I sure would like to have it the right way, and know what this doesn't work in the first place...






Old topic!
Guest, the last post of this topic is over 60 days old and at this point you may not reply in this topic. If you wish to continue this conversation start a new topic.



PARTNERS