Here I go...

This is my shader, I used 4 neighbor points instead of 6, looks fine.

// Vertex Shader for Water Surface Texture Processing - 2
// With normal generate on the fly ver.

// Register declarations

// c0 : WorldViewProjection Matrix
// c4 : WorldView Matrix
// c8-c9: View-Rotation Correction Matrix
// c10 : Water color( r, g, b, a )
//
//
// v0 : Vertex Position
// v1 : 4 Neighbor Heights: x:left, y: right, z: up, w:down

// oPos : Homogenous Position of Vertex
// oT0 : Refraction Texture Coordinate
// oT1 : Reflection Texture Coordinate
// oD0 : Diffuse color

vs.1.1
dcl_position v0
dcl_texcoord v1

def c11, 0.675, -0.9, 0.5, 0.0
def c12, 0.3, -0.3, -1.0, 1.0

// Transform to screen space
dp4 r0.x, v0, c0
dp4 r0.y, v0, c1
dp4 r0.z, v0, c2
dp4 r0.w, v0, c3

mov oPos, r0
mov oD0, c10

// Get reciprocal of w;
rcp r0.w, r0.w

// Transform to view space as texture coordinates
dp4 r1.x, v0, c4
dp4 r1.y, v0, c5
dp4 r1.z, v0, c6


// Do projection divison
rcp r1.z, r1.z
mul r1.xy, r1.xy, r1.zz;

// Transform to view space
mad r1.xy, r1.xy, c11.xy, c11.zz

// Generate Normal by getting difference between neighbors
mov r2.w, v0.y
sub r3.xw, r2.ww, v1.xw
sub r3.yz, v1.yz, r2.ww
add r2.xz, r3.xz, r3.yw

// Normalize Normal
mov r2.y, c12.w
dp3 r8.x, r2.xyz, r2.xyz
rsq r8.xyz, r8.x
mul r5.xyz, r2.xyz, r8.xyz

// Transform normal using correction rotation matrix
dp3 r6.x, r5.xz, c8.xy
dp3 r6.y, r5.xz, c9.xy

// Scale displacement by distance of vertex
mul r6.xy, r6.xy, r0.ww

// Calculate refraction
mad oT0.xy, r6.xy, c12.xy, r1.xy

// Calculate reflection
mad oT1.xy, r6.xy, c12.zw, r1.xy

Crazying for Programmable Graphics Cards...