float4x4	WorldViewProj		: VIEW_PROJECTION_MATRIX;
float3		LightDir			: LIGHTDIRECTION;
float4		SunColorIntensity	: SUNCOLORINTENSITY;
float3		EyePos				: EYEPOSITION;

float3		BR = { 0.000000650, 0.000000610, 0.000000475 }; //		: BETARAYLEIGH;
float3		BM = { 0.00000125, 0.00000125, 0.00000125 }; //			: BETAMIE;

struct VS_INPUT
{
	float4 pos				: POSITION;
	float3 vnormal			: NORMAL;
	float2 tex0				: TEXCOORD0;
};

struct VS_OUTPUT
{
	float4 pos		: POSITION;
	float4 diff		: COLOR;
};

VS_OUTPUT VS(VS_INPUT input)
{
	VS_OUTPUT output;
	
	// Transform position
	output.pos = mul(input.pos, WorldViewProj);
	
	float g = 0.3;

	float s = length(EyePos - input.pos.xyz);
	
	float3 F_ex = exp((BM + BR) * (-s));
	
	float3 v = normalize(input.pos.xyz - EyePos);
	float theta = dot(LightDir, v);
	
	// (1-g)^2 / (1+g^2 - 2g*theta)^(3/2)
	float hg = pow(1.0-g,2.0) / pow((1.0+pow(g,2.0) - 2.0*g*theta), 1.5);
	
	float3 bethaR = BR * ((3.0/(16*3.14159)) * (1 + theta*theta));
	float3 bethaM = BM * ((1.0/(4.0*3.14159)) * hg);
	
	float3 L_in = ((bethaR + bethaM) / (BR + BM)) * (1-F_ex);
	L_in *= SunColorIntensity.xyz;
	L_in *= SunColorIntensity.w;
	
	output.diff = float4(L_in,1);
	
	return output;
}

// PS
float4 PS(VS_OUTPUT input) : COLOR
{
	return input.diff;
}

technique T0
{
	pass P0
	{
		LightingEnable = false;
		DepthTestEnable = false;
		CullFaceEnable = false;
		VertexProgram = compile arbvp1 VS();
		FragmentProgram = compile arbfp1 PS() ;
	}
}