Hi! Ive purchased a book by frank D. Luna and im stuck on tutorial 6.
Basically the book shows you how to create and render lights seperately in the scene, but for the life of me i cant get 2 lights to render at the same time. Here are the shader codes:
//=============================================================================
// lighthelper.fx by Frank Luna (C) 2008 All Rights Reserved.
//
// Structures and functions for lighting calculations.
//=============================================================================
struct Light
{
float3 pos;
float3 dir;
float4 ambient;
float4 diffuse;
float4 spec;
float3 att;
float spotPower;
float range;
};
struct SurfaceInfo
{
float3 pos;
float3 normal;
float4 diffuse;
float4 spec;
};
float3 ParallelLight(SurfaceInfo v, Light L, float3 eyePos)
{
float3 litColor = float3(0.0f, 0.0f, 0.0f);
// The light vector aims opposite the direction the light rays travel.
float3 lightVec = -L.dir;
// Add the ambient term.
litColor += v.diffuse * L.ambient;
// Add diffuse and specular term, provided the surface is in
// the line of site of the light.
float diffuseFactor = dot(lightVec, v.normal);
[branch]
if( diffuseFactor > 0.0f )
{
float specPower = max(v.spec.a, 1.0f);
float3 toEye = normalize(eyePos - v.pos);
float3 R = reflect(-lightVec, v.normal);
float specFactor = pow(max(dot(R, toEye), 0.0f), specPower);
// diffuse and specular terms
litColor += diffuseFactor * v.diffuse * L.diffuse;
litColor += specFactor * v.spec * L.spec;
}
return litColor;
}
float3 PointLight(SurfaceInfo v, Light L, float3 eyePos)
{
float3 litColor = float3(0.0f, 0.0f, 0.0f);
// The vector from the surface to the light.
float3 lightVec = L.pos - v.pos;
// The distance from surface to light.
float d = length(lightVec);
if( d > L.range )
return float3(0.0f, 0.0f, 0.0f);
// Normalize the light vector.
lightVec /= d;
// Add the ambient light term.
litColor += v.diffuse * L.ambient;
// Add diffuse and specular term, provided the surface is in
// the line of site of the light.
float diffuseFactor = dot(lightVec, v.normal);
[branch]
if( diffuseFactor > 0.0f )
{
float specPower = max(v.spec.a, 1.0f);
float3 toEye = normalize(eyePos - v.pos);
float3 R = reflect(-lightVec, v.normal);
float specFactor = pow(max(dot(R, toEye), 0.0f), specPower);
// diffuse and specular terms
litColor += diffuseFactor * v.diffuse * L.diffuse;
litColor += specFactor * v.spec * L.spec;
}
// attenuate
return litColor / dot(L.att, float3(1.0f, d, d*d));
}
float3 Spotlight(SurfaceInfo v, Light L, float3 eyePos)
{
float3 litColor = PointLight(v, L, eyePos);
// The vector from the surface to the light.
float3 lightVec = normalize(L.pos - v.pos);
float s = pow(max(dot(-lightVec, L.dir), 0.0f), L.spotPower);
// Scale color by spotlight factor.
return litColor*s;
}
And the other effect file is...
//=============================================================================
// lighting.fx by Frank Luna (C) 2008 All Rights Reserved.
//
// Transforms and lights geometry.
//=============================================================================
#include "lighthelper.fx"
cbuffer cbPerFrame
{
Light gLight;
int gLightType;
float3 gEyePosW;
};
cbuffer cbPerObject
{
float4x4 gWorld;
float4x4 gWVP;
};
struct VS_IN
{
float3 posL : POSITION;
float3 normalL : NORMAL;
float4 diffuse : DIFFUSE;
float4 spec : SPECULAR;
};
struct VS_OUT
{
float4 posH : SV_POSITION;
float3 posW : POSITION;
float3 normalW : NORMAL;
float4 diffuse : DIFFUSE;
float4 spec : SPECULAR;
};
VS_OUT VS(VS_IN vIn)
{
VS_OUT vOut;
// Transform to world space space.
vOut.posW = mul(float4(vIn.posL, 1.0f), gWorld);
vOut.normalW = mul(float4(vIn.normalL, 0.0f), gWorld);
// Transform to homogeneous clip space.
vOut.posH = mul(float4(vIn.posL, 1.0f), gWVP);
// Output vertex attributes for interpolation across triangle.
vOut.diffuse = vIn.diffuse;
vOut.spec = vIn.spec;
return vOut;
}
float4 PS(VS_OUT pIn) : SV_Target
{
// Interpolating normal can make it not be of unit length so normalize it.
pIn.normalW = normalize(pIn.normalW);
SurfaceInfo v = {pIn.posW, pIn.normalW, pIn.diffuse, pIn.spec};
float3 litColor;
float3 litColor2;
if( gLightType == 0 ) // Parallel
{
litColor = ParallelLight(v, gLight, gEyePosW);
}
else if( gLightType == 1 ) // Point
{
litColor = PointLight(v, gLight, gEyePosW);
}
else // Spot
{
litColor = Spotlight(v, gLight, gEyePosW);
}
return float4(litColor, pIn.diffuse.a);
}
technique10 LightTech
{
pass P0
{
SetVertexShader( CompileShader( vs_4_0, VS() ) );
SetGeometryShader( NULL );
SetPixelShader( CompileShader( ps_4_0, PS() ) );
}
}
Is it a case of adding 2 colors together? Do i have to use a special function to do this? Ive been stuck on this problem for a really long time! PLEASE HELP ME!
