• Advertisement
Sign in to follow this  

If statement weird behavior

This topic is 1918 days old which is more than the 365 day threshold we allow for new replies. Please post a new topic.

If you intended to correct an error in the post then please contact us.

Recommended Posts

In my HLSL shader code I'm checking if an bool effect parameter is true or not. I get really weird results and can't see any logic in it at all. Here's what happens,

With 100 skinned meshes that uses normal mapping my game runs at around 24fps, without normal mapping it's around 130fps. I want to make normal mapping optional so I therefor added an effect parameter (gUseNormalMap) that decides if it should be used or not.

I did this for testing:

[CODE]
cbuffer cbPerObject
{
bool gUseNormalMap;
}

...

if(gUseNormalMap)
{
float3 normalMapSample = gNormalMap.Sample(samLinear, pin.Tex).rgb;
pin.NormalW = NormalSampleToWorldSpace(normalMapSample, pin.NormalW, pin.TangentW);
}
else
return float4(0, 1, 0, 1);
[/CODE]

If I set gUseNormalMap to true the fps is ~24 like it should be, but when I set it to false the fps still is 24 which it shouldn't be without normal mapping. What's makes it more weird is that the color of the mesh is green and that's correct since the else statement returns float4(0, 1, 0, 1). [u]It's like both bodies of the if statement runs when gUseNormalMap is = false.[/u]

I also tested without using the effect parameter,

[CODE]// Use normal mapping?
bool normalMapping = false;
if(normalMapping)
{
float3 normalMapSample = gNormalMap.Sample(samLinear, pin.Tex).rgb;
pin.NormalW = NormalSampleToWorldSpace(normalMapSample, pin.NormalW, pin.TangentW);
}
else
return float4(0, 1, 0, 1);[/CODE]

but that gives the expected output. I hope I was clear enough and that someone knows what's going on!

Share this post


Link to post
Share on other sites
Advertisement
Hmm maybe an issue with the constant buffer in the c++ code? Also it might be better to have them as a separate effect? So that you don't have an if statement per pixel.

Share this post


Link to post
Share on other sites
Evaluating an if statement takes many cycles -- it may be that the math inside [font=courier new,courier,monospace]NormalSampleToWorldSpace[/font] is just as expensive as the branch itself.

You'll have to use a GPU profiler rather than just looking at your frame-rate to see what's going on in detail.

Share this post


Link to post
Share on other sites
The compiler is almost certainly flattening that branch, or moving the texture sample outside of the branch. This is because you can't use Texture2D.Sample inside a branch, since that function requires the gradients of the texture coordinate in order to perform mip level selection and/or anisotropic filtering. Gradient operations are undefined inside of a branch, since the neighboring pixels in the 2x2 quad might not take the same path through code. So if you want to branch around texture samples, you need to do something like this:

[code]

float2 tcGradX = ddx(pin.Tex);
float2 tcGradY = ddy(pin.Tex);

// Force the compiler to issue a branch instruction
[branch]
if(gUseNormalMap)
{
float3 normalMapSample = gNormalMap.SampleGrad(samLinear, pin.Tex, tcGradX, tcGradY).rgb;
pin.NormalW = NormalSampleToWorldSpace(normalMapSample, pin.NormalW, pin.TangentW);
}
else
return float4(0, 1, 0, 1);
[/code] Edited by MJP

Share this post


Link to post
Share on other sites
i keep wanting to think interpolation, but i dont even know if you're passing it through the vertex shader or not lol

Share this post


Link to post
Share on other sites
Thanks for the replies! I haven't got it to work but I'm probably just going to add a separate technique that uses a pixel shader containing the normal mapping instead. But that means I will copy and paste a lot of code which feels stupid. I'm not that experienced with HLSL so I don't really know the workflow of it, maybe this is usual?

[quote name='Daniel_RT' timestamp='1350257838' post='4990189']
Hmm maybe an issue with the constant buffer in the c++ code? Also it might be better to have them as a separate effect? So that you don't have an if statement per pixel.
[/quote]

That means a lot of code duplicates, is it worth it just for one if-statement?

Also, where can I find out about exceptions in HLSL like the one MJP mentioned about that you cannot use Texture2D.Sample inside a branch? Edited by simpler

Share this post


Link to post
Share on other sites
[quote name='simpler' timestamp='1350516581' post='4991277']
But that means I will copy and paste a lot of code which feels stupid
[/quote]You can use #include and functions instead of copy&pasting.[quote]That means a lot of code duplicates, is it worth it just for one if-statement?[/quote]Most commercial game engines build tools that can compile a single source file into many different shaders (to remove branches, etc). A few years ago I wrote a terrain shader which the engine exploded into about 400 different pixel shaders, which it would select based on which features were required (e.g. material blending, normal mapping, etc). So, yeah, using many different variations of a similar shader is "normal".

On my last project we did something simpler, where I would write variations by hand like:
[code]//variation1.hlsl
#include "core.hlsl"

//variation2.hlsl
#define ENABLE_NORMAL_MAPPING
#include "core.hlsl"

//core.hlsl
...
#if defined(ENABLE_NORMAL_MAPPING)
return gNormalMap.Sample(samLinear, pin.Tex);
#else
return float4(0, 1, 0, 1);
#endif
...[/code] Edited by Hodgman

Share this post


Link to post
Share on other sites
My 2 cents

The following document, in one of its sections explains how to do conditional compilation.

[url="http://d3dcoder.net/Data/Resources/d3d11Metro.pdf"]http://d3dcoder.net/Data/Resources/d3d11Metro.pdf[/url]

Share this post


Link to post
Share on other sites
Sign in to follow this  

  • Advertisement