• Announcements

    • khawk

      Download the Game Design and Indie Game Marketing Freebook   07/19/17

      GameDev.net and CRC Press have teamed up to bring a free ebook of content curated from top titles published by CRC Press. The freebook, Practices of Game Design & Indie Game Marketing, includes chapters from The Art of Game Design: A Book of Lenses, A Practical Guide to Indie Game Marketing, and An Architectural Approach to Level Design. The GameDev.net FreeBook is relevant to game designers, developers, and those interested in learning more about the challenges in game development. We know game development can be a tough discipline and business, so we picked several chapters from CRC Press titles that we thought would be of interest to you, the GameDev.net audience, in your journey to design, develop, and market your next game. The free ebook is available through CRC Press by clicking here. The Curated Books The Art of Game Design: A Book of Lenses, Second Edition, by Jesse Schell Presents 100+ sets of questions, or different lenses, for viewing a game’s design, encompassing diverse fields such as psychology, architecture, music, film, software engineering, theme park design, mathematics, anthropology, and more. Written by one of the world's top game designers, this book describes the deepest and most fundamental principles of game design, demonstrating how tactics used in board, card, and athletic games also work in video games. It provides practical instruction on creating world-class games that will be played again and again. View it here. A Practical Guide to Indie Game Marketing, by Joel Dreskin Marketing is an essential but too frequently overlooked or minimized component of the release plan for indie games. A Practical Guide to Indie Game Marketing provides you with the tools needed to build visibility and sell your indie games. With special focus on those developers with small budgets and limited staff and resources, this book is packed with tangible recommendations and techniques that you can put to use immediately. As a seasoned professional of the indie game arena, author Joel Dreskin gives you insight into practical, real-world experiences of marketing numerous successful games and also provides stories of the failures. View it here. An Architectural Approach to Level Design This is one of the first books to integrate architectural and spatial design theory with the field of level design. The book presents architectural techniques and theories for level designers to use in their own work. It connects architecture and level design in different ways that address the practical elements of how designers construct space and the experiential elements of how and why humans interact with this space. Throughout the text, readers learn skills for spatial layout, evoking emotion through gamespaces, and creating better levels through architectural theory. View it here. Learn more and download the ebook by clicking here. Did you know? GameDev.net and CRC Press also recently teamed up to bring GDNet+ Members up to a 20% discount on all CRC Press books. Learn more about this and other benefits here.
Sign in to follow this  
Followers 0
gboxentertainment

Voxelization using Dominant Axis (Voxel Cone Tracing)

6 posts in this topic

I am trying to voxelize my scene by rasterization using the dominant axis theory - which involves using the vertex normals to find the dominant axis of each triangle which would then determine the direction to apply an orthographic projection of the scene. This is done in the geometry shader and then passed to the fragment shader.

 

I manage to voxelize the scene, except for one major problem as shown below, adjacent to the non-voxelized scene:

[attachment=13606:givox0.jpg][attachment=13608:givox1.jpg]

 

Notice how there are artifacts above the Buddha and the Sphere?

 

Does anyone know what could be the cause of this and how this can be fixed?

 

Here is my geometry shader code:

#version 430

layout(triangles) in;
layout(triangle_strip, max_vertices=3) out;

in VSOutput
{
	vec4 ndcPos;
	vec4 fNorm;
	vec2 fTexCoord;
	vec4 worldPos;
} vsout[];

out GSOutput
{
	vec4 ndcPos;
	vec4 fNorm;
	vec2 fTexCoord;
	vec4 worldPos;
	vec4 axisCol;
	mat4 oProj;
} gsout;

uniform mat4 voxSpace;

void main()
{
	gsout.oProj = mat4(0.0);

	for(int i = 0; i<gl_in.length(); i++)
	{	
		
		vec4 n = vsout[i].fNorm;

		gsout.fNorm = n;
		gsout.fTexCoord = vsout[i].fTexCoord;
		gsout.worldPos = vsout[i].worldPos;
		
		float maxC = max(abs(n.x), max(abs(n.y), abs(n.z)));
		float x,y,z;
		x = abs(n.x) < maxC ? 0.0 : 1.0;
		y = abs(n.y) < maxC ? 0.0 : 1.0;
		z = abs(n.z) < maxC ? 0.0 : 1.0;

		vec4 axis = vec4(x,y,z,1);
		
		if(axis == vec4(1.0,0.0,0.0,1))
		{
			gsout.oProj[0] = vec4(0,0,-1,0);
			gsout.oProj[1] = vec4(0,-1,0,0);
			gsout.oProj[2] = vec4(-1,0,0,0);
			gsout.oProj[3] = vec4(0,0,0,1);
		}	
		else if(axis == vec4(0,1,0,1))
		{
			gsout.oProj[0] = vec4(1,0,0,0);
			gsout.oProj[1] = vec4(0,0,1,0);
			gsout.oProj[2] = vec4(0,-1,0,0);
			gsout.oProj[3] = vec4(0,0,0,1);
		}
		else if(axis == vec4(0,0,1,1))
		{
			gsout.oProj[0] = vec4(1,0,0,0);
			gsout.oProj[1] = vec4(0,-1,0,0);
			gsout.oProj[2] = vec4(0,0,-1,0);
			gsout.oProj[3] = vec4(0,0,0,1);
		}
		
		gsout.axisCol = axis;

		gl_Position = gsout.oProj*voxSpace*gl_in[i].gl_Position;
		gsout.ndcPos = gsout.oProj*voxSpace*vsout[i].ndcPos;

		EmitVertex();
	}
	
}
Edited by gboxentertainment
0

Share this post


Link to post
Share on other sites

 which involves using the vertex normals to find the dominant axis of each triangle 

is that a typo or you're really doing that? (it's not fully clear to me from your source, but it seems like).

 

you need to calculate the face normal, in the GS, not using the Vertex normals, all vertices per face need to be transformed in the same way. could explain those random voxelizations you got for the sphere and buddah, and the broken edges of your cube.

1

Share this post


Link to post
Share on other sites

Cheers Krypt0n,

 

The moment you mentioned face normal, I realised immediately what was wrong. Here's the results:

[attachment=13609:givox2.jpg]

 

and here's the corrected code:

#version 430

layout(triangles) in;
layout(triangle_strip, max_vertices=3) out;
//layout(binding = 0) uniform atomic_uint ac;

in VSOutput
{
	vec4 ndcPos;
	vec4 fNorm;
	vec2 fTexCoord;
	vec4 worldPos;
} vsout[];

out GSOutput
{
	vec4 ndcPos;
	vec4 fNorm;
	vec2 fTexCoord;
	vec4 worldPos;
	vec4 axisCol;
	mat4 oProj;
} gsout;

uniform mat4 voxSpace;

void main()
{
	gsout.oProj = mat4(0.0);

	vec4 n = normalize(vsout[0].fNorm);

	for(int i = 0; i<gl_in.length(); i++)
	{	
		gsout.fNorm = n;
		
		float maxC = max(abs(n.x), max(abs(n.y), abs(n.z)));
		float x,y,z;
		x = abs(n.x) < maxC ? 0.0 : 1.0;
		y = abs(n.y) < maxC ? 0.0 : 1.0;
		z = abs(n.z) < maxC ? 0.0 : 1.0;

		vec4 axis = vec4(x,y,z,1);
		
		if(axis == vec4(1.0,0.0,0.0,1))
		{
			gsout.oProj[0] = vec4(0,0,-1,0);
			gsout.oProj[1] = vec4(0,-1,0,0);
			gsout.oProj[2] = vec4(-1,0,0,0);
			gsout.oProj[3] = vec4(0,0,0,1);
		}	
		else if(axis == vec4(0,1,0,1))
		{
			gsout.oProj[0] = vec4(1,0,0,0);
			gsout.oProj[1] = vec4(0,0,1,0);
			gsout.oProj[2] = vec4(0,-1,0,0);
			gsout.oProj[3] = vec4(0,0,0,1);
		}
		else if(axis == vec4(0,0,1,1))
		{
			gsout.oProj[0] = vec4(1,0,0,0);
			gsout.oProj[1] = vec4(0,-1,0,0);
			gsout.oProj[2] = vec4(0,0,-1,0);
			gsout.oProj[3] = vec4(0,0,0,1);
		}
		
		gsout.axisCol = axis;

		gl_Position = gsout.oProj*voxSpace*gl_in[i].gl_Position;
		gsout.ndcPos = gsout.oProj*voxSpace*vsout[i].ndcPos;
		gsout.fTexCoord = vsout[i].fTexCoord;
		gsout.worldPos = vsout[i].worldPos;

		EmitVertex();
	}
	
}

 

Now the new challenge with switching from 6-directional 3d textures for storing my voxels to a single 3d texture is sampling anisotropically for voxel cone tracing.

Originally this was my code:

vec4 sampleVox(vec3 pos, vec3 dir, float lod)
{
	vec4 sampleX = dir.x < 0.0 ? textureLod(voxTex[0], pos, lod) : textureLod(voxTex[1], pos, lod);
	vec4 sampleY = dir.y < 0.0 ? textureLod(voxTex[2], pos, lod) : textureLod(voxTex[3], pos, lod);
	vec4 sampleZ = dir.z < 0.0 ? textureLod(voxTex[4], pos, lod) : textureLod(voxTex[5], pos, lod);
	
	vec3 wts = abs(dir);

	float invSampleMag = 1.0/(wts.x + wts.y + wts.z + 0.0001);
	wts *= invSampleMag;

	vec4 filtered = (sampleX*wts.x + sampleY*wts.y + sampleZ*wts.z)/10;

	return filtered;
}

 

where 'dir' is the direction of the cone that I'm tracing. I guess I would just offset 'pos' by 1 voxel in each direction?

 

[EDIT]

 

So I've tried offsetting 'pos' by 1 voxel for each direction to get anisotropic sampling - seems to work:

 

[attachment=13610:givox3.jpg][attachment=13611:givox4.jpg]

 

Here's the code:

vec4 sampleVox(vec3 pos, vec3 dir)
{
	vec4 sampleX = dir.x < 0.0 ? textureLod(sampler0, pos-vec3(1,0,0)/voxDim, 0) : textureLod(sampler0, pos+vec3(1,0,0)/64.0, 0);
	vec4 sampleY = dir.y < 0.0 ? textureLod(sampler0, pos-vec3(0,1,0)/voxDim, 0) : textureLod(sampler0, pos+vec3(0,1,0)/64.0, 0);
	vec4 sampleZ = dir.z < 0.0 ? textureLod(sampler0, pos-vec3(0,0,1)/voxDim, 0) : textureLod(sampler0, pos+vec3(0,0,1)/64.0, 0);
	vec3 wts = abs(dir);
	float invSampleMag = 1.0/(wts.x + wts.y + wts.z + 0.0001);
	wts *= invSampleMag;
	vec4 filtered = (sampleX*wts.x+sampleY*wts.y+sampleZ*wts.z);

	return filtered;
}

 

I will share results once I have implemented this into my voxel cone tracer and have proven that it is anisotropically sampled.

Edited by gboxentertainment
0

Share this post


Link to post
Share on other sites

Okay, so I implemented the dominant axis voxelization into my voxel cone tracer. Here are the results:

 

[attachment=13612:vct3.jpg][attachment=13613:givox5.jpg]

 

Aside from the very soft and very voxelized shadows, the main artifact is the diffuse reflection from the red box caused by the illumination sampled from the base mip - this is due to the voxelized box being extruded out too much. I'm not using conservative voxelization by the way.

I don't think I've got the soft shadowing calculation right either, all I'm doing is just taking the vct function and tracing a single cone in the direction of the light.

 

Here is my vct code:

 

#version 430

in vec4 fNorm;
in vec2 fTexCoord;
in vec4 worldPos;
out vec4 fColor;

uniform sampler2D sampler0;

layout(binding = 1) uniform sampler3D voxTex;

uniform mat4 worldSpace;
uniform mat4 voxTexSpace;

uniform float voxDim;

uniform vec4 baseCol;
uniform float specConeRatio;
uniform vec4 lightPos;
uniform vec4 lightDir;
uniform vec3 camPos;

float minVoxDiam = 1/voxDim;

vec4 sampleVox(vec3 pos, vec3 dir, float lod)
{
	vec4 sampleX = dir.x < 0.0 ? textureLod(voxTex, pos-vec3(1,0,0)/voxDim, lod) : textureLod(voxTex, pos+vec3(1,0,0)/voxDim, lod);
	vec4 sampleY = dir.y < 0.0 ? textureLod(voxTex, pos-vec3(0,1,0)/voxDim, lod) : textureLod(voxTex, pos+vec3(0,1,0)/voxDim, lod);
	vec4 sampleZ = dir.z < 0.0 ? textureLod(voxTex, pos-vec3(0,0,1)/voxDim, lod) : textureLod(voxTex, pos+vec3(0,0,1)/voxDim, lod);
	
	vec3 wts = abs(dir);

	float invSampleMag = 1.0/(wts.x + wts.y + wts.z + 0.0001);
	wts *= invSampleMag;

	vec4 filtered = (sampleX*wts.x + sampleY*wts.y + sampleZ*wts.z)/10;

	return filtered;
}

vec4 coneTrace(vec3 o, vec3 d, float coneRatio, float maxDist)
{
	vec3 samplePos = o;
	vec4 accum = vec4(0.0);
	float minDiam = 1.0/voxDim;
	float startDist = minDiam;

	float dist = startDist;
	while(dist <= maxDist && accum.w < 1.0)
	{
		float sampleDiam = max(minDiam, coneRatio*dist);
		float sampleLOD = log2(sampleDiam*voxDim);
		vec3 samplePos = o + d*dist;
		vec4 sampleVal = sampleVox(samplePos, -d, sampleLOD);

		float sampleWt = (1.0 - accum.w);
		accum += sampleVal * sampleWt;

		dist += sampleDiam;
	}

	accum.xyz *= 8.0;

	return accum;
}

vec4 shadowConeTrace(vec3 o, vec3 d, float coneRatio, float maxDist)
{
	vec3 samplePos = o;
	vec4 accum = vec4(0.0);
	float minDiam = 1/voxDim;
	float startDist = minDiam;

	float dist = startDist;
	while(dist <= maxDist && accum.w < 1.0)
	{
		float sampleDiam = max(minDiam, coneRatio*dist);
		float sampleLOD = log2(sampleDiam*voxDim);
		vec3 samplePos = o + d*dist;
		vec4 sampleVal = sampleVox(samplePos, -d, sampleLOD);

		float sampleWt = (1.0 - accum.w);
		accum += sampleVal * sampleWt;

		dist += sampleDiam;
	}

	accum.xyz *= 2.0;

	return accum;
}

void main()
{
	vec4 color = vec4(0,0,0,0);
	vec4 texMap = texture(sampler0, fTexCoord);
	vec4 voxPos = voxTexSpace*worldPos;
	voxPos.xyz *= 1.0/voxPos.w;

	//Direct Lighting
	vec4 L = normalize(lightPos - worldPos);
	vec4 D = normalize(lightDir);
	float spotAngle = dot(-L, D);
	float outerCone = 0.7;
	float innerCone = 0.2;
	float spot = clamp((spotAngle - outerCone)/innerCone, 0.0, 1.0);
	float dist = length(L);
	vec4 N = normalize(fNorm);
	float I = max(dot(N, L), 0.0);
	
	if(I > 0.0)
		color += I*spot;

	//Specular Reflection
	vec3 spec;
	vec3 viewToFrag = normalize(worldPos.xyz - camPos);
	vec3 reflDir = reflect(viewToFrag, N.xyz);
	spec = specConeRatio <= 1.0 ? coneTrace(voxPos.xyz, reflDir, specConeRatio, 0.3).xyz : vec3(0);

	//Indirect Lighting
	vec3 iDiffuse = vec3(0);
	float iConeRatio = 0.9;
	float iMaxDist = 0.3;
	iDiffuse += coneTrace(voxPos.xyz, N.xyz, iConeRatio, iMaxDist).xyz;
	iDiffuse += 0.707*coneTrace(voxPos.xyz, N.xyz+vec3(1,0,0), iConeRatio, iMaxDist).xyz;
	iDiffuse += 0.707*coneTrace(voxPos.xyz, N.xyz+vec3(0,1,0), iConeRatio, iMaxDist).xyz;
	iDiffuse += 0.707*coneTrace(voxPos.xyz, N.xyz+vec3(0,0,1), iConeRatio, iMaxDist).xyz;
	iDiffuse += 0.707*coneTrace(voxPos.xyz, N.xyz+vec3(0,-1,0), iConeRatio, iMaxDist).xyz;
	vec4 shadowComp = vec4(0);
	shadowComp += shadowConeTrace(voxPos.xyz, L.xyz, 0.3, 0.4);
	float shadow = (shadowComp.x+shadowComp.y+shadowComp.z)*4;

	fColor.xyz = ((color.xyz/2+iDiffuse)*baseCol.xyz*texMap.xyz+spec)*(1-shadow);
	fColor.w = color.w*1;
}

 

 

Hopefully someone will come up with some tips to help me improve this.

 

[EDIT]

 

On second thoughts, it might actually be the shadowing calc that's causing the artifact with the red box.

Edited by gboxentertainment
1

Share this post


Link to post
Share on other sites

Here's some results on performance with various tests on my gtx485m at 1024 x 768 resolution and 64x64x64 voxel dimensions:

 

6-directional texture voxelization:

With anisotropic sampling enabled: ~25 to 30fps

I can't really disable anisotropic sampling for this test because that would mean most voxels would not be captured.

 

Dominant axis voxelization:

With anisotropic sampling enabled: ~25 to 35fps (that's if I get real close to the high-res Buddha).

With anisotropic sampling disabled: ~60fps (double the fps!)

 

There does not seem to be much noticeable difference in quality - although this is yet to be tested properly.

I guess disabling anisotropic sampling significantly reduces the amount of calculations done for every mip level during the cone tracing.

0

Share this post


Link to post
Share on other sites

I'd suggest trying to pre-voxelize everything and just inject it into your grid. I really don't understand why there was the insistence on re-voxelization every frame, except maybe because the voxel cone tracing paper was more academic than practical initially. Certainly dynamic re-voxelization might be useful for dynamic destruction/other physics/deformation stuff. But really, most of your stuff is just going to a static model, and even animated models can be voxelized and transformed.

 

Why waste all those resources rasterizing everything multiple times per frame? That being said, if you really do have something that needs to be re-rasterized, you can use Epic's trick of marking things as static and checking each frame to see if they actually need to be re-voxelized. Otherwise they just re-use the previous voxelization. Anyway, it's looking good.

Edited by Frenetic Pony
0

Share this post


Link to post
Share on other sites

Why waste all those resources rasterizing everything multiple times per frame? That being said, if you really do have something that needs to be re-rasterized, you can use Epic's trick of marking things as static and checking each frame to see if they actually need to be re-voxelized.

 

For this scene:

Dominant axis voxelization (anisotropic sampling enabled):

Static pre-voxelization once during initialization: ~25 to 35 fps

Dynamic voxelization per frame: ~25 to 35fps

 

Majority of the cost is actually in the cone tracing, which is why when I turn off anisotropic sampling there is such a massive increase in framerate - however, I have found out that anisotropic filtering is required for more physically accurate lighting, particularly with specular where the cone ratio is much smaller.

Of course, if I implemented an octree system, then the cost of building the octree might be too much for a per frame basis. Likewise if I had a more complex scene. Ultimately, the plan for this particular test scene was to keep the walls and floor static and the objects dynamic so that I can move them around to demonstrate the lighting effect. However, this is low on my priority list - something that I would implement at the end after I've corrected all noticeable artifacts.

 

At the moment, my aim is to get the lighting as accurate as possible. Then I would worry about performance. This is a hobby research project - I am not trying to create a game.

 

Anyhow, check out my latest semi-success in soft shadowing using vct:

[attachment=13621:giboxshadows.jpg][attachment=13622:giboxshadows1.jpg][attachment=13623:giboxshadows2.jpg]

 

float sampleVoxShadows(vec3 pos, vec3 dir, float lod)
{
	float shadowSamp = textureLod(voxTex, pos, lod).w;

	return shadowSamp;
}

float shadowConeTrace(vec3 o, vec3 d, float coneRatio, float maxDist)
{
	vec3 samplePos = o;
	float sampleVal = 0.0;
	float accum = 0.0;
	float minDiam = 1/voxDim;
	float startDist = minDiam;

	float dist = startDist;
	while(dist <= maxDist && accum < 1.0)
	{
		float sampleDiam = max(minDiam, coneRatio*dist);
		float sampleLOD = log2(sampleDiam*voxDim);
		vec3 samplePos = o + d*dist;
		sampleVal = sampleVoxShadows(samplePos, -d, sampleLOD);

		float sampleWt = (1.0 - accum);
		accum += sampleVal * sampleWt;

		dist += sampleDiam;
	}

	return accum;
}

	float shadow = 0;
	shadow += shadowConeTrace(voxPos.xyz, L.xyz, 0.1, 1.0);

	fColor.xyz = ((color.xyz*(1-shadow)+iDiffuse.xyz)*baseCol.xyz*texMap.xyz+spec); 

 

I just need to figure out a way to remove the voxelized self-shadowing artifacts that are apparent on the blue sphere.

I also need to work out how to remove or reduce the add-on effect that the radiance has on direct lighting.

Edited by gboxentertainment
0

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0