Jump to content
  • Advertisement
Sign in to follow this  

How does the Physics of Flappy Bird works?

This topic is 2059 days old which is more than the 365 day threshold we allow for new replies. Please post a new topic.

If you intended to correct an error in the post then please contact us.

Recommended Posts


From watching a Youtube video, it seems to me that there is not much physics (as in buyoant force vs gravity) involved at all.

It looks more somewhat like:

    height -= 2;
    if(tapped) height += 3;


    if(is_wall(xpos, height))
Edited by samoth

Share this post

Link to post
Share on other sites

I made a flappy bird clone called "Buzzy Bee" in CoffeeScript and HTML5 (because my teacher started making one and I wanted to make a better one :P). The source is on Github: https://github.com/dr01d3k4/BuzzyBee and you can play it on jsfiddle: http://jsfiddle.net/dr01d3k4/BGAD7/


The physics are pretty simple. It doesn't use Box2D because the vertical motion is handled by simple integration and collision is just AABB with no resolution (because instant game over, though may get a bit harder if you want to add a dieing animation). All the code for the game logic is in game_screen.coffee. Here are the important parts (commented to explain)

# In the constructor, declare a player object (@ means self/this)
# The velocity and acceleration are both vertical, horizontal movement is handled differently
@player =
	velocity: 0
	acceleration: GRAVITY
	rotation: 0

# Create the pipes (fixed amount that get recycled) and keep track of where the first one is
# The player doesn't actually move horizontally - the pipes do
@firstPipeX = START_PIPE_X
@pipes = [ ]
for i in [0...PIPE_COUNT]
	@pipes.push @newPipe()

# The methods for creating new pipes (as a JavaScript object)

newPipe: -> baseHeight: @randomPipeHeight(), gapHeight: PIPE_GAP_HEIGHT, width: PIPE_WIDTH, scored: no

# When the player jumps, set his velocity to jump velocity and add some rotation for graphical effect
playerJump: ->
	@player.velocity = JUMP_VELOCITY
	@player.rotation = PLAYER_JUMP_ROTATION

# Game logic with some parts like AI and trail taken out
update: (deltaTime) ->
	@time += deltaTime
	# This is just for graphical effect
	@player.rotation += PLAYER_ROTATION_SPEED * deltaTime

	# Jump if the player is pressing the correct keys and is actually playing
	# (In the menu screen, the game is played by the AI and uses the same code so these @playerControlled checks are common)
	@playerJump() if @playerControlled and (isKeyPressed(Key.JUMP) or isMousePressed())

	# Simple integration vertically
	@player.velocity += @player.acceleration * deltaTime
	@player.y += @player.velocity * deltaTime

	# Check if the player's gone out of bounds
	if @player.y + @player.height > SCREEN_HEIGHT
		@player.y = SCREEN_HEIGHT - @player.height
		@player.velocity = 0
		@gameOver() if @playerControlled

	if @player.y < 0
		@player.y = 0
		@player.velocity = 0
		@gameOver() if @playerControlled

	# Offset the first pipe by the speed of the player
	# Negative because player going to right, so pipes must go to the left for same effect
	@firstPipeX -= MOVE_SPEED * deltaTime

	# If the first pipe's gone off screen
	if @firstPipeX < -PIPE_WIDTH * 2
		# Remove the first pipe by moving each down
		for i in [1...@pipes.length]
			@pipes[i - 1] = @pipes[i]

		# Add a new pipe
		# However probably would be more efficient to reuse the first that was removed
		@pipes[PIPE_COUNT - 1] = @newPipe()

		# Because the first pipe was removed, need to reset this back to position of new first pipe

	# Check player not rotating too much
	@player.rotation = -PLAYER_MAX_ROTATION if @player.rotation < -PLAYER_MAX_ROTATION
	@player.rotation = PLAYER_MAX_ROTATION if @player.rotation > PLAYER_MAX_ROTATION

	# Detect collision and scoring
	x = @firstPipeX
	collision = no
	for pipe in @pipes
		# Only if the left of the pipe is to the left of the player's right (i.e player's going through/gone past)
		# Ones further on get skipped
		if x < @player.x + @player.width
			# If the right of the pipe is on right of player's left
			# And the player isn't inside the gap
			# Then collided
			# Like AABB intersection but y is negated
			if x + pipe.width > @player.x and (@player.y + @player.height > SCREEN_HEIGHT - pipe.baseHeight or @player.y < SCREEN_HEIGHT - pipe.baseHeight - pipe.gapHeight)
				collision = yes

			# If the right of the pipe is on the left of the player
			if x + pipe.width <= @player.x
				# And it hasn't already been used for scoring
				# Then the player has gone through this pipe and so gains a point
				@score += 1 unless pipe.scored
				pipe.scored = yes

		# Update the pipe's left position to the one of the next pipe
		x += pipe.width + PIPE_GAP_HORIZONTAL

	# Player hit a pipe and so game over
	return @gameOver() if collision and @playerControlled

Share this post

Link to post
Share on other sites
Sign in to follow this  

  • Advertisement

Important Information

By using GameDev.net, you agree to our community Guidelines, Terms of Use, and Privacy Policy.

GameDev.net is your game development community. Create an account for your GameDev Portfolio and participate in the largest developer community in the games industry.

Sign me up!