• Create Account

## DX11 - Dual Paraboloid Mapping - One Render Pass

Old topic!

Guest, the last post of this topic is over 60 days old and at this point you may not reply in this topic. If you wish to continue this conversation start a new topic.

12 replies to this topic

### #1Migi0027 (肉コーダ)  Members

Posted 09 August 2013 - 06:13 AM

Hi guys,

I'm trying to approach the method of Dual Paraboloid Mapping, the method itself is integrated, now I'm thinking of optimizations, like can it be integrated in one render pass. Recently I have been informed that you can use multiple camera views in one pass with using the geometry shader, and then exporting to different render targets, whether this would be a performance improvement, I can't tell as I have never done it.

Question 1. How can the geometry shader be used to export multiple SV_Positions according to the render targets?

When reading a theoretical and practical paper on Dual Paraboloid Mapping by Jazon Zink, he explained the artifacts that can appear, which I receive myself.

Question 2. Is there a way to fake away these artifacts, or a proper method to?

Thank You, as always.

FastCall22: "I want to make the distinction that my laptop is a whore-box that connects to different network"

Blog about... stuff (GDNet, WordPress): www.gamedev.net/blog/1882-the-cuboid-zone/cuboidzone.wordpress.com/

### #2Migi0027 (肉コーダ)  Members

Posted 10 August 2013 - 03:34 AM

I just realized something, when coming close to the vertices, they somehow jump:

So when any vertex come to the corner of the screen, they jump away.

FastCall22: "I want to make the distinction that my laptop is a whore-box that connects to different network"

Blog about... stuff (GDNet, WordPress): www.gamedev.net/blog/1882-the-cuboid-zone/cuboidzone.wordpress.com/

### #3Jason Z  Members

Posted 10 August 2013 - 06:44 AM

The implementation for rendering a single pass dual paraboloid map can be found in Hieroglyph 3 (see the MirrorMirror sample).  In there, I use the geometry shader to render both paraboloid maps at once.  To be honest, I never tried to do it in a two pass method, so I can't really give any real information about comparing the speeds.  Some people stay away from the geometry shader at all costs, but I haven't really had any performance problems while using it.  Just as FYI, there is a chapter in Practical Rendering and Computation with Direct3D 11 that deals with setting up the single pass rendering of dual paraboloid maps.

What is probably happening with your vertices is that once they go behind the paraboloid's center point then the method used to find the vertex position puts it on the opposite side of the paraboloid map.  You should detect when this is the case and either clip the pixels affected or clamp the vertex position to the plane where z = 0 in paraboloid space.

Fixing the issues with primitive size is not really possible unless you tessellate things a bit better.  You could use a stronger LOD system, or possibly use the tessellation stages to improve the tessellation based on paraboloid map size.  But again, you may run into performance problems with the additional stages being active...

Jason Zink :: DirectX MVP

Direct3D 11 engine on CodePlex: Hieroglyph 3

Games: Lunar Rift

### #4Migi0027 (肉コーダ)  Members

Posted 10 August 2013 - 07:39 AM

About the issue with the vertices, it still appears, here's what I do:

VS: // After applying world*view*proj
output.position = output.position / output.position.w;

// The decider between the front and back side
output.position.z *= _dpmSetting;

float L = length( output.position.xyz );
output.position = output.position / L;

output.z_value = output.position.z;

output.position.z = output.position.z + 1;
output.position.x = output.position.x / output.position.z;
output.position.y = output.position.y / output.position.z;

output.position.z = L / 500;							// set a depth value for correct z-buffering
output.position.w = 1;									// set w to 1 so there is no w divide

PS:
clip( input.z_value );


But no luck.

FastCall22: "I want to make the distinction that my laptop is a whore-box that connects to different network"

Blog about... stuff (GDNet, WordPress): www.gamedev.net/blog/1882-the-cuboid-zone/cuboidzone.wordpress.com/

### #5Jason Z  Members

Posted 10 August 2013 - 09:20 AM

Do you have a culling mode enabled?  Either back face or front face culling?

Jason Zink :: DirectX MVP

Direct3D 11 engine on CodePlex: Hieroglyph 3

Games: Lunar Rift

### #6Migi0027 (肉コーダ)  Members

Posted 10 August 2013 - 10:49 AM

This is how I initialize my D3D11_RASTERIZER_DESC stage:

D3D11_RASTERIZER_DESC rasterizerState;
rasterizerState.FillMode = D3D11_FILL_SOLID;
rasterizerState.CullMode = D3D11_CULL_BACK;
rasterizerState.FrontCounterClockwise = false;
rasterizerState.DepthBias = false;
rasterizerState.DepthBiasClamp = 0;
rasterizerState.SlopeScaledDepthBias = 0;
rasterizerState.DepthClipEnable = true;
rasterizerState.ScissorEnable = true;
rasterizerState.MultisampleEnable = false;
rasterizerState.AntialiasedLineEnable = false;


But nothing changed, though I may have done it wrong.

FastCall22: "I want to make the distinction that my laptop is a whore-box that connects to different network"

Blog about... stuff (GDNet, WordPress): www.gamedev.net/blog/1882-the-cuboid-zone/cuboidzone.wordpress.com/

### #7Migi0027 (肉コーダ)  Members

Posted 13 August 2013 - 03:47 AM

Well after countless tries, I can't seem to solve the jumping of vertices.

output.position = output.position / output.position.w;

When this line is removed the problem no longer persists, but again, that creates another issue as the map doesn't become correct.

Creation of D3D11_RASTERIZER_DESC :
D3D11_RASTERIZER_DESC rasterizerState;
rasterizerState.FillMode = D3D11_FILL_SOLID;
rasterizerState.CullMode = D3D11_CULL_BACK;
rasterizerState.FrontCounterClockwise = false;
rasterizerState.DepthBias = false;
rasterizerState.DepthBiasClamp = 0;
rasterizerState.SlopeScaledDepthBias = 0;
rasterizerState.DepthClipEnable = true;
rasterizerState.ScissorEnable = true;
rasterizerState.MultisampleEnable = false;
rasterizerState.AntialiasedLineEnable = false;

dev->CreateRasterizerState(&rasterizerState, &RsRMAP);


VS
output.position = mul(position, worldMatrix);
output.position = mul(output.position, viewMatrix);
output.position = mul(output.position, projectionMatrix);

output.position = output.position / output.position.w;

// The decider between the front and back side
output.position.z *= _dpmSetting; // 1 front || -1 back

// Determine the distance between the paraboloid origin and the vertex.
float L = length( output.position.xyz );

// Normalize the vector to the vertex
output.position = output.position / L;

// Save the z-component of the normalized vector
output.z_value = output.position.z;

output.position.z = output.position.z + 1;
output.position.x = output.position.x / output.position.z;
output.position.y = output.position.y / output.position.z;
output.position.z = (L - 0.1)/(500.0-0.1);

output.position.w = 1;

PS
clip( input.z_value );


Now what on the earth have I done wrong... again...

Edited by Migi0027, 13 August 2013 - 03:50 AM.

FastCall22: "I want to make the distinction that my laptop is a whore-box that connects to different network"

Blog about... stuff (GDNet, WordPress): www.gamedev.net/blog/1882-the-cuboid-zone/cuboidzone.wordpress.com/

### #8Jason Z  Members

Posted 13 August 2013 - 04:15 AM

As a test, I would say to change the color of the vertices based on their output.z_value attribute.  If the value is greater than 0, then use one color, and if it is less than 0 use another color.  This will help you identify which vertices you should be displaying and which ones should not be.  I am willing to bet that the ones that you shouldn't see are the ones jumping to the other side.  This geometry should be captured in the other paraboloid map, and hence be clipped from the current one.  In fact, that is why it jumps - because the paraboloid transformation is only correct when z > 0!

Jason Zink :: DirectX MVP

Direct3D 11 engine on CodePlex: Hieroglyph 3

Games: Lunar Rift

### #9Migi0027 (肉コーダ)  Members

Posted 13 August 2013 - 06:13 AM

Result:

HLSL:

if ( input.z_value > 0)
{
output.Diffuse = float4(0, 1, 0, 1);
}
else
{
output.Diffuse = float4(1, 0, 0, 1);
}

clip( input.z_value );

output.Lighting = float4(1, 1, 1, 1);

return output;


I must be doing something really stupid right now.

FastCall22: "I want to make the distinction that my laptop is a whore-box that connects to different network"

Blog about... stuff (GDNet, WordPress): www.gamedev.net/blog/1882-the-cuboid-zone/cuboidzone.wordpress.com/

### #10unbird  Members

Posted 13 August 2013 - 11:35 AM

The clip( input.z_value ) makes your debug rendering useless: All the red colors will now vanish

### #11Migi0027 (肉コーダ)  Members

Posted 13 August 2013 - 12:19 PM

GOD I feel stupid right now! (╯°□°）╯...︵...︵ ┻━┻

Without that line of hell, here is the output:

I still wonder how the hell I did that  .

FastCall22: "I want to make the distinction that my laptop is a whore-box that connects to different network"

Blog about... stuff (GDNet, WordPress): www.gamedev.net/blog/1882-the-cuboid-zone/cuboidzone.wordpress.com/

### #12unbird  Members

Posted 13 August 2013 - 12:34 PM

Not giving much of a clue. I think Jason nailed it and the backface culling should already solve the probelm.

But I think I see (part of) the actual problem now (*browsing Hieroglyph*). Ah yeah. Dual paraboloid is a projection . But you're doing it after your (usual) projection, so projecting twice (and likely wrong). This is the vertex shader from the Hieroglyph sample:

struct VS_INPUT
{
float3 position : POSITION;
float2 tex		: TEXCOORDS0;
};

struct GS_INPUT
{
float4 position : SV_Position;
float2 tex		: TEXCOORD0;
float  z_value  : ZVALUE;
};

GS_INPUT VSMAIN( VS_INPUT IN )
{
GS_INPUT OUT;

// Transform the vertex to be relative to the paraboloid's basis.
OUT.position = mul( float4( IN.position, 1 ), WorldViewMatrix );

// Determine the distance between the paraboloid origin and the vertex.
float L = length( OUT.position.xyz );

// Normalize the vector to the vertex
OUT.position = OUT.position / L;

// Save the z-component of the normalized vector
OUT.z_value = OUT.position.z;

// Store the distance to the vertex for use in the depth buffer.
OUT.position.z = L / 500;

// Set w to 1 since we aren't doing any perspective distortion.
OUT.position.w = 1;

// Pass through texture coordinates
OUT.tex	= IN.tex;

return OUT;
}

Edit: Oops, geometry shader is needed too:
struct PS_INPUT
{
float4 position : SV_Position;
float2 tex      : TEXCOORD0;
float  z_value  : ZVALUE;
uint   rtindex  : SV_RenderTargetArrayIndex;
};
//-----------------------------------------------------------------------------
[maxvertexcount(3)]
[instance(2)]
void GSMAIN( triangle GS_INPUT input[3],
uint id : SV_GSInstanceID,
inout TriangleStream<PS_INPUT> OutputStream )
{
PS_INPUT output;

// Initialize the vertex order and the direction of the paraboloid.
uint3 order = uint3( 0, 1, 2 );
float direction = 1.0f;

// Check to see which copy of the primitive this is.  If it is 0, then it
// is considered the front facing paraboloid.  If it is 1, then it is
// considered the back facing paraboloid.  For back facing, we reverse
// the output vertex winding order.
if ( id == 1 )
{
order.xyz = order.xzy;
direction = -1.0f;
}

// Emit three vertices for one complete triangle.
for ( int i = 0; i < 3; i++ )
{
// Create a projection factor, which determines which half space
// will be considered positive and also adds the viewing vector
// which is (0,0,1) and hence can only be added to the z-component.
float projFactor = input[order[i]].z_value * direction + 1.0f;
output.position.x = input[order[i]].position.x / projFactor;
output.position.y = input[order[i]].position.y / projFactor;
output.position.z = input[order[i]].position.z;
output.position.w = 1.0f;

// Simply use the geometry shader instance as the render target
// index for this primitive.
output.rtindex = id;

// Pass through the texture coordinates to the pixel shader
output.tex = input[order[i]].tex;

output.z_value = input[order[i]].z_value * direction;

// Write the vertex to the output stream.
OutputStream.Append(output);
}

OutputStream.RestartStrip();
}

Edited by unbird, 13 August 2013 - 12:38 PM.

### #13Migi0027 (肉コーダ)  Members

Posted 13 August 2013 - 12:52 PM

Alright the map is better, but is it perfect? ┬──┬ ノ( ゜-゜ノ)

PS. Don't mind the weird shadow placement!

Edited by Migi0027, 13 August 2013 - 12:52 PM.

FastCall22: "I want to make the distinction that my laptop is a whore-box that connects to different network"

Blog about... stuff (GDNet, WordPress): www.gamedev.net/blog/1882-the-cuboid-zone/cuboidzone.wordpress.com/

Old topic!

Guest, the last post of this topic is over 60 days old and at this point you may not reply in this topic. If you wish to continue this conversation start a new topic.