I am making use of https://github.com/ashima/webgl-noise/wiki as part of a procedural texture generation routine in a GLSL fragment shader, specifically the pnoise() function as part of the fragment shader found here: https://github.com/ashima/webgl-noise/blob/master/src/classicnoise3D.glsl#L39, as follows:

// Classic Perlin noise
float cnoise(vec3 P)
{
  vec3 Pi0 = floor(P); // Integer part for indexing
  vec3 Pi1 = Pi0 + vec3(1.0); // Integer part + 1
  Pi0 = mod289(Pi0);
  Pi1 = mod289(Pi1);
  vec3 Pf0 = fract(P); // Fractional part for interpolation
  vec3 Pf1 = Pf0 - vec3(1.0); // Fractional part - 1.0
  vec4 ix = vec4(Pi0.x, Pi1.x, Pi0.x, Pi1.x);
  vec4 iy = vec4(Pi0.yy, Pi1.yy);
  vec4 iz0 = Pi0.zzzz;
  vec4 iz1 = Pi1.zzzz;

  vec4 ixy = permute(permute(ix) + iy);
  vec4 ixy0 = permute(ixy + iz0);
  vec4 ixy1 = permute(ixy + iz1);

  vec4 gx0 = ixy0 * (1.0 / 7.0);
  vec4 gy0 = fract(floor(gx0) * (1.0 / 7.0)) - 0.5;
  gx0 = fract(gx0);
  vec4 gz0 = vec4(0.5) - abs(gx0) - abs(gy0);
  vec4 sz0 = step(gz0, vec4(0.0));
  gx0 -= sz0 * (step(0.0, gx0) - 0.5);
  gy0 -= sz0 * (step(0.0, gy0) - 0.5);

  vec4 gx1 = ixy1 * (1.0 / 7.0);
  vec4 gy1 = fract(floor(gx1) * (1.0 / 7.0)) - 0.5;
  gx1 = fract(gx1);
  vec4 gz1 = vec4(0.5) - abs(gx1) - abs(gy1);
  vec4 sz1 = step(gz1, vec4(0.0));
  gx1 -= sz1 * (step(0.0, gx1) - 0.5);
  gy1 -= sz1 * (step(0.0, gy1) - 0.5);

  vec3 g000 = vec3(gx0.x,gy0.x,gz0.x);
  vec3 g100 = vec3(gx0.y,gy0.y,gz0.y);
  vec3 g010 = vec3(gx0.z,gy0.z,gz0.z);
  vec3 g110 = vec3(gx0.w,gy0.w,gz0.w);
  vec3 g001 = vec3(gx1.x,gy1.x,gz1.x);
  vec3 g101 = vec3(gx1.y,gy1.y,gz1.y);
  vec3 g011 = vec3(gx1.z,gy1.z,gz1.z);
  vec3 g111 = vec3(gx1.w,gy1.w,gz1.w);

  vec4 norm0 = taylorInvSqrt(vec4(dot(g000, g000), dot(g010, g010), dot(g100, g100), dot(g110, g110)));
  g000 *= norm0.x;
  g010 *= norm0.y;
  g100 *= norm0.z;
  g110 *= norm0.w;
  vec4 norm1 = taylorInvSqrt(vec4(dot(g001, g001), dot(g011, g011), dot(g101, g101), dot(g111, g111)));
  g001 *= norm1.x;
  g011 *= norm1.y;
  g101 *= norm1.z;
  g111 *= norm1.w;

  float n000 = dot(g000, Pf0);
  float n100 = dot(g100, vec3(Pf1.x, Pf0.yz));
  float n010 = dot(g010, vec3(Pf0.x, Pf1.y, Pf0.z));
  float n110 = dot(g110, vec3(Pf1.xy, Pf0.z));
  float n001 = dot(g001, vec3(Pf0.xy, Pf1.z));
  float n101 = dot(g101, vec3(Pf1.x, Pf0.y, Pf1.z));
  float n011 = dot(g011, vec3(Pf0.x, Pf1.yz));
  float n111 = dot(g111, Pf1);

  vec3 fade_xyz = fade(Pf0);
  vec4 n_z = mix(vec4(n000, n100, n010, n110), vec4(n001, n101, n011, n111), fade_xyz.z);
  vec2 n_yz = mix(n_z.xy, n_z.zw, fade_xyz.y);
  float n_xyz = mix(n_yz.x, n_yz.y, fade_xyz.x); 
  return 2.2 * n_xyz;
}

I am making use of the three-dimensional periodic perlin noise generation function to generate tiling two-dimensional texture data; the perlin noise seed is passed into the third dimension (z) and I can generate a new seed at will.

Since the third dimension of the periodic repetition accepts a noise seed instead of a coordinate on the z-axis, I have slightly modified the first few lines of the pnoise() function to discard the modulus of this third dimension. I replaced this:

vec3 Pi0 = floor(P); // Integer part for indexing
vec3 Pi1 = Pi0 + vec3(1.0); // Integer part + 1

With this:

vec3 Pi0   = mod( floor( P   ), rep );
     Pi0.z =      floor( P.z );
 
vec3 Pi1   = mod( Pi0   + vec3(1.0), rep );
     Pi1.z =      Pi0.z +      1.0;  

That works just fine.

Anyway, what I am trying to do is scale the noise on the two x and y dimensions. This would be useful for generation textures such as wood panels and so forth; by stretching one of the two dimensions.

I have written a higher level function to accept global uniform variables as part of my own fragment shader that makes use of this modified pnoise() function, as here:

uniform vec2 cell_size; // draw operation width and height

uniform s32 seed = 0;

f32 noise( vec2 scale, vec2 offset, f32 depth, f32 strength )
{
  depth = pow( 2.0, depth );

  return pnoise( vec3( gl_FragCoord.xy * scale + offset * cell_size * scale, ( seed * depth ) ) / depth,
    vec3( cell_size, 0.0 ) / depth ) * strength;
}

Unfortunately, the scaling (as per vec2 scale parameter) is not working as I have intended. I have taken a screenshot of the scaled function so that you can see it is not tiling properly:



Anybody have any ideas on how to fix the scaling?

Cheers!

Damn, you guys suck. If you post some pictures of beer in this thread I will post the solution I discovered.

Excellent, I love weissbraus.

I discovered that the periodic repetition only worked properly when scaled to powers of two. This meant that I had to compromise a little bit, but I don't think this will really be a problem because the loss of scaling finesse can be solved simply by tinkering with higher depths of perlin noise.

As such, the final code for my function is:

f32 noise( vec2 scale, vec2 offset, f32 depth, f32 strength )
{
  depth = pow( 2.0, depth );

  scale.x = pow( 2.0, floor( scale.x ) );
  scale.y = pow( 2.0, floor( scale.y ) );

  return perlin( vec3( gl_FragCoord.xy * scale + offset * cell_size * scale,
    ( seed * depth ) ) / depth,
    vec3( cell_size * scale, 0.0 ) / depth ) * strength;
}

I am limited at the moment to using scale ratios to the power of two, ie. 2:1, 4:1, 8:1 etc. but I think this is a fair compromise to the problem at least for the moment. I don't think I will be able to support scaling at arbitrary ratios without writing my own noise generation algorithm or severally modifying webgl-noise's source even more; I'm not a computer scientist or mathematician so I will leave that for another day or person to figure out. Perlin and simplex noise are tried and true and as a game developer I do not think it is my destiny to write replacements for them.